mysql-gui-tools-5.0_p3.ebuild

mysql-gui-tools-5.0_p3.ebuild (text/plain), 1.97 KB, created by Sven Wegener on 2006-09-17 12:14:47 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit gnome2 eutils

MY_P="${P/_p/r}"

DESCRIPTION="MySQL GUI Tools"
HOMEPAGE="http://www.mysql.com/products/tools/"
SRC_URI="mirror://mysql/Downloads/MySQLGUITools/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="java php python gtk nls"

RDEPEND=">=x11-libs/gtk+-2.6
	>=dev-libs/glib-2.6
	>=gnome-base/libglade-2.5
	>=dev-libs/libsigc++-2.0
	>=dev-libs/libpcre-4.4
	>=dev-libs/libxml2-2.6.2
	=dev-cpp/glibmm-2.8*
	=dev-cpp/gtkmm-2.8*
	=gnome-extra/gtkhtml-3.10*
	>=dev-db/mysql-5	"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.15
	>=app-text/scrollkeeper-0.3.11"

S="${WORKDIR}"/${MY_P}

pkg_setup() {
	einfo
	einfo "This package includes the following components:"
	einfo "- MySQL Administrator"
	einfo "- MySQL Query Browser"
	einfo "- MySQL Workbench (currently disabled)"
	einfo
}

src_unpack() {
	gnome2_src_unpack

	cd "${S}"
	epatch "${FILESDIR}"/${PV}-lua-modules.patch
}

src_compile() {
	cd "${S}"/mysql-gui-common
	econf \
		--enable-grt \
		$(use_enable php php-modules) \
		$(use_enable python python-modules) \
		$(use_enable java java-modules) \
		$(use_enable gtk) \
		$(use_enable nls i18n) \
		|| die "econf failed"
	emake || die "emake failed"

	cd "${S}"/mysql-administrator
	econf \
		$(use_enable nls i18n) \
		|| die "econf failed"
	emake || die "emake failed"

	cd "${S}"/mysql-query-browser
	econf \
		--with-gtkhtml=libgtkhtml-3.8 \
		|| die "econf failed"
	emake || die "emake failed"

#	cd "${S}"/mysql-workbench
#	econf || die "econf failed"
#	emake || die "emake failed"
}

src_install() {
	USE_DESTDIR=1

	cd "${S}"/mysql-gui-common
	gnome2_src_install || die "gnome2_src_install failed"

	cd "${S}"/mysql-administrator
	gnome2_src_install || die "gnome2_src_install failed"

	cd "${S}"/mysql-query-browser
	gnome2_src_install || die "gnome2_src_install failed"

#	cd "${S}"/mysql-workbench
#	gnome2_src_install || die "gnome2_src_install failed"
}