hamster-3.0.2.ebuild

hamster-3.0.2.ebuild (text/plain), 1.40 KB, created by Nikita Zlobin on 2022-11-19 21:49:15 UTC

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI="7"

PYTHON_COMPAT=( python3_{5..11} )
PYTHON_REQ_USE="threads(+)"

inherit python-single-r1 xdg gnome2-utils waf-utils

DESCRIPTION="Time tracking for the masses"
HOMEPAGE="https://github.com/projecthamster http://projecthamster.org"
SRC_URI="https://github.com/projecthamster/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="
	${PYTHON_DEPS}
	dev-libs/glib:2
	$(python_gen_cond_dep '
		dev-python/pygobject[${PYTHON_USEDEP}]
		dev-python/pycairo[${PYTHON_USEDEP}]
		dev-python/dbus-python[${PYTHON_USEDEP}]
		dev-python/pyxdg[${PYTHON_USEDEP}]
	')
	x11-libs/gtk+:3[introspection]
	sys-devel/gettext
	dev-util/itstool
	gnome-extra/yelp
"
DEPEND="
	${RDEPEND}
	dev-util/intltool
"
BDEPEND="
	$(python_gen_cond_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
"

pkg_setup() {
	python-single-r1_pkg_setup
}

src_prepare() {
	default
	python_fix_shebang --force .
}

src_configure() {
	waf-utils_src_configure --skip-icon-cache-update --skip-gsettings
}

src_install() {
	waf-utils_src_install
	insinto '/usr/share/glib-2.0/schemas'
	doins 'data/org.gnome.hamster.gschema.xml'
}

pkg_preinst() {
	xdg_pkg_preinst
	gnome2_schemas_savelist
}

pkg_postinst() {
	xdg_pkg_postinst
	gnome2_schemas_update
}

pkg_postrm() {
	xdg_pkg_postrm
	gnome2_schemas_update
}