Ebuild for 0.0.1

gdk-pixbuf-loader-webp-0.0.1.ebuild (text/plain), 932 bytes, created by bzoloid on 2020-05-30 19:31:17 UTC

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit meson gnome2-utils

DESCRIPTION="WebP Image format GdkPixbuf loader"
HOMEPAGE="https://github.com/aruiz/webp-pixbuf-loader"
SRC_URI="https://github.com/aruiz/webp-pixbuf-loader/archive/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/webp-pixbuf-loader-${PV}"

LICENSE="LGPL-2+"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="test"

RDEPEND="
	>=media-libs/libwebp-0.4.3:=
	>=x11-libs/gdk-pixbuf-2.22
"
DEPEND="${RDEPEND}"
BDEPEND="
	virtual/pkgconfig
"

src_prepare() {
	default

	# Disable unsafe update of pixbuf loaders cache
	sed -ie 's/^\(meson.add_install_script\)/#\1/g' "${S}/meson.build" || die

	if ! use test; then
		sed -ie 's/^\(subdir\)/#\1/g' "${S}/meson.build" || die
	fi
}

pkg_preinst() {
	gnome2_gdk_pixbuf_savelist
}

pkg_postinst() {
	gnome2_gdk_pixbuf_update
}

pkg_postrm() {
	gnome2_gdk_pixbuf_update
}