gens-2.15.5-r1.ebuild

gens-2.15.5-r1.ebuild (text/plain), 1.12 KB, created by Alex on 2016-09-11 00:11:41 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5
inherit eutils flag-o-matic games pax-utils

DESCRIPTION="A Sega Genesis/CD/32X emulator"
HOMEPAGE="http://sourceforge.net/projects/gens/"
SRC_URI="mirror://sourceforge/gens/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 amd64"
IUSE=""

RDEPEND="virtual/opengl[abi_x86_32(-)]
	>=media-libs/libsdl-1.2[joystick,video,abi_x86_32(-)]
	x11-libs/gtk+:2[abi_x86_32(-)]
"
DEPEND="${RDEPEND}
	>=dev-lang/nasm-0.98
"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-romsdir.patch \
		"${FILESDIR}"/${P}-as-needed.patch \
		"${FILESDIR}"/${P}-ovflfix.patch \
		"${FILESDIR}"/${P}-gcc34.patch
	sed -i -e '1i#define OF(x) x' src/gens/util/file/unzip.h || die
	append-ldflags -Wl,-z,noexecstack
}

src_configure() {
	use amd64 && multilib_toolchain_setup x86
	egamesconf \
		--disable-gtktest \
		--disable-sdltest || die
}

src_install() {
	DOCS="AUTHORS BUGS README gens.txt history.txt" \
		default
	pax-mark m "${ED}usr/games/bin/gens"
	newicon pixmaps/gens_small.png ${PN}.png
	make_desktop_entry "${PN}" "Gens"
	prepgamesdirs
}