ulogd-2.0.2-r1.ebuild

ulogd-2.0.2-r1.ebuild (text/plain), 2.94 KB, created by Coacher on 2013-03-14 23:51:41 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="5"

inherit autotools eutils linux-info user

DESCRIPTION="A userspace logging daemon for netfilter/iptables related logging"
HOMEPAGE="http://netfilter.org/projects/ulogd/index.html"
SRC_URI="http://ftp.netfilter.org/pub/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc pcap mysql postgres sqlite dbi +nflog +nfct nfacct"

RDEPEND="net-firewall/iptables
	>=net-libs/libnfnetlink-1.0.1
	>=net-libs/libmnl-1.0.3
	nflog? ( >=net-libs/libnetfilter_log-1.0.0 )
	nfct? ( >=net-libs/libnetfilter_conntrack-1.0.2 )
	nfacct? ( >=net-libs/libnetfilter_acct-1.0.1 )
	pcap? ( net-libs/libpcap )
	mysql? ( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	sqlite? ( dev-db/sqlite:3 )
	dbi? ( dev-db/libdbi )"

DEPEND="${RDEPEND}
	doc? (
			app-text/linuxdoc-tools
			virtual/latex-base
			app-text/texlive-core
		)"

pkg_setup() {
	enewgroup ulogd
	enewuser ulogd -1 -1 /var/log/ulogd ulogd
	if [ ! -d /var/log/ulogd ]; then
		checkpath -q -d -m 0750 -o ulogd /var/log/ulogd
	fi

	linux-info_pkg_setup

	if kernel_is lt 2 6 14; then
		die "ulogd2 requires kernel newer than 2.6.14"
	fi

	if kernel_is lt 2 6 18; then
		ewarn
		ewarn "You are using kernel older than 2.6.18"
		ewarn "Some ulogd2 features may be unavailable"
		ewarn
	fi

	if use nfacct && kernel_is lt 3 3 0; then
		die "NFACCT input plugin requires kernel newer than 3.3.0"
	fi
}

src_prepare() {
	# fix automagic support of dbi, pcap and sqlite3 output plugins
	epatch "${FILESDIR}/${P}-automagic.patch"

	# make all logs to be kept in a single dir /var/log/ulogd
	sed -i 's/var\/log/var\/log\/ulogd/g' "${S}"/ulogd.conf.in

	# place sockets in /var/run instead of /tmp
	sed -i 's/tmp/var\/run/g' "${S}"/ulogd.conf.in

	eautoreconf
}

src_configure() {
	econf \
		$(use_with dbi) \
		$(use_with pcap) \
		$(use_with mysql) \
		$(use_with postgres pgsql) \
		$(use_with sqlite) \
		$(use_enable nflog) \
		$(use_enable nfct) \
		$(use_enable nfacct)
}

src_compile() {
	emake

	if use doc ; then
		# prevent access violations from generation of bitmap font files
		export VARTEXFONTS="${T}"/fonts
		emake -C doc
	fi
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc AUTHORS README

	if use doc ; then
		dohtml doc/ulogd.html
		dodoc doc/ulogd.dvi
		dodoc doc/ulogd.txt
		dodoc doc/ulogd.ps
	fi

	use sqlite && dodoc doc/sqlite3.table
	use mysql && dodoc doc/mysql-*.sql
	use postgres && dodoc doc/pgsql-*.sql

	insinto /etc
	doins ulogd.conf

	newinitd "${FILESDIR}/ulogd.init" ulogd

	insinto /etc/logrotate.d
	newins "${FILESDIR}/ulogd.logrotate" ulogd

	doman ulogd.8
}

pkg_preinst() {
	fowners root:ulogd /etc/ulogd.conf
	fperms 640 /etc/ulogd.conf
}

pkg_postinst() {
	if ! has_version 'app-admin/ulogd'; then
		elog
		elog "You must have at least one logging stack enabled to make ulogd work."
		elog "Please edit example configuration located at /etc/ulogd.conf"
		elog
	fi
}