lifelines-3.0.37.2.ebuild - Revised ebuild

lifelines-3.0.37.2.ebuild (text/plain), 1.56 KB, created by Olivier Fisette (RETIRED) on 2004-06-06 19:17:32 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header$

DESCRIPTION="Lifelines is an open source genealogy program."
HOMEPAGE="${PN}.sf.net"
SRC_URI="mirror://sourceforge//${PN}/${P}.tar.bz2"
LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
DEPEND="virtual/glibc
		nls? sys-devel/gettext
		doc? app-text/docbook-sgml-utils"
IUSE="doc nls"

src_compile() {
	# So that "make install" does not try to install documentation in
	# /usr/share/doc/lifelines.
	sed -ie 's/SUBDIRS = build intl po win32 src docs reports tt/SUBDIRS = build intl po src reports tt/' Makefile.in
	local myconf
	use nls || myconf='--disable-nls'
	econf ${myconf} || die
	emake || die
	cd docs
	# If app-text/docbook-sgml-utils is installed, documents are built from
	# source using the jw tools.
	emake || die
}

src_install() {
	make install DESTDIR=${D} || die
	dodoc AUTHORS ChangeLog NEWS README README.DEVELOPERS README.INTERNATIONAL
	doman docs/{btedit.1,dbverify.1,llines.1}
	insinto /usr/share/doc/${P}/manuals
	# The PDF docs are not installed, since they are corrupted.
	use doc && doins docs/*.jpg docs/*.html docs/*.txt
	# Adds the graphics for the reports HTML index, and a config file example.
	insinto /usr/share/${PN}
	doins reports/boc.gif reports/ll.png
	newins .linesrc linesrc.example
	# Installs the reports.
	insinto /usr/share/${PN}/reports/
	doins reports/*.ll reports/*.tex reports/CREDIT reports/README
	insinto /usr/share/${PN}/reports/st
	doins reports/st/*.ll
	# Installs the env file.
	insinto /etc/env.d
	doins ${FILESDIR}/25lifelines
}