scid-vs-pc.4.7.ebuild

scid-vs-pc-4.7.ebuild (text/plain), 1.87 KB, created by Godfath3r on 2012-04-02 10:11:31 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
PYTHON_DEPEND="2"
inherit eutils toolchain-funcs python games

MY_P="${PN//-/_}-${PV}"
DESCRIPTION="A free chess database application"
HOMEPAGE="http://scidvspc.sourceforge.net/"
SRC_URI="mirror://sourceforge/scidvspc/${MY_P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=">=dev-lang/tk-8.5.10-r1
	>=sys-libs/zlib-1.2.5-r2"
RDEPEND="${DEPEND}
	!games-board/chessdb
	!games-board/scid
	x11-libs/libX11"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	python_set_active_version 2
	games_pkg_setup
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	epatch "${FILESDIR}"/${P}-qa-warnings.patch

	sed -i -e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}/${PN}:" \
		tcl/config.tcl || die "sed failed"

	sed -i -e "/CFLAGS/s/-O2/${CFLAGS}/" configure || die

	python_convert_shebangs -r 2 .
}

src_configure() {
	# configure is not an autotools script
	./configure \
		COMPILE="$(tc-getCXX)" \
		LINK="$(tc-getCXX) ${LDFLAGS}" \
		CXX="$(tc-getCXX)" \
		CC="$(tc-getCC)" \
		TCL_INCLUDE="" \
		BINDIR="${GAMES_BINDIR}" \
		SHAREDIR="${GAMES_DATADIR}/${PN}" \
		|| die "configure failed"
}

src_compile() {
	emake all_scid || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install_scid || die "emake install failed"
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r sounds || die "failed installing sounds"

	dodoc README_Scid_vs_PC doc/{CHANGES,ChangeLog,README,THANKS,TODO}
	dohtml htdocs/*.html

	newicon icons/scid.png ${PN}.png
	make_desktop_entry scid "Scid vs. PC" ${PN} "Game;BoardGame"

	doins scidlet.sbk || die "Failed installing scidlet.sbk"

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	elog "To enable speech, emerge dev-tcltk/snack"
	elog "To enable some piece sets, emerge dev-tcltk/tkimg"
	elog "To enable Xfcc support, emerge dev-tcltk/tdom"
}