jack-audio-connection-kit-1.9.7.ebuild

jack-audio-connection-kit-1.9.7.ebuild (text/plain), 2.04 KB, created by Gavin Pryke on 2011-05-05 18:54:33 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3
inherit waf-utils multilib toolchain-funcs

DESCRIPTION="JACK is a sound server system for handling real-time, low latency audio and MIDI"
HOMEPAGE="http://www.jackaudio.org"
SRC_URI="http://www.grame.fr/~letz/jack-${PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa +dbus jackd multilib"

RDEPEND=">=media-libs/libsndfile-1.0.23
	>=media-libs/libsamplerate-0.1.7
	alsa? ( >=media-libs/alsa-lib-1.0.23 )
	dbus? ( >=sys-apps/dbus-1.4.6 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/jack-${PV}
DOCS="ChangeLog README README_NETJACK2 TODO"
# needs to be set as we do not use waf-utils_src_configure and build will fail
WAF_BINARY=${S}/waf

pkg_setup() {
	if ! use dbus && ! use jackd ; then
		eerror "For ${PN} to function,"
		eerror "USE=\"dbus\" and/or USE=\"jackd\" flags need to be enabled"
		die "Invalid USE flags for ${PN} package, enable dbus and/or jackd"
	fi
}

src_configure() {
	local mylibdir=
	if use multilib || has_multilib_profile ; then
		mylibdir="--libdir=/$(get_libdir)"
	else
		mylibdir="--libdir32=/$(get_libdir)"
	fi

	local myconf="--prefix=${EPREFIX}/usr --mandir=/share/man/man1 ${mylibdir}"
	use alsa && myconf="${myconf} --alsa"
	use dbus && myconf="${myconf} --dbus"
	use jackd && myconf="${myconf} --classic"
	use multilib || has_multilib_profile && myconf="${myconf} --mixed"

	tc-export CC CXX CPP AR RANLIB
	# not using waf-utils_src_configure here as this breaks the multilib
	# locations for the jack library, emulate what waf-utils would do instead
	CCFLAGS="${CFLAGS}" LINKFLAGS="${LDFLAGS}" ./waf configure ${myconf} || die
}

pkg_postinst() {
	if ! use alsa; then
		einfo "NOTE: alsa has not been enabled as a USE flag, enable it to"
		einfo "utilise alsa and drive your sound card for audio output"
	fi
	if use dbus && use jackd; then
		einfo "WARNING !! mixing both jackd and jackdbus may cause issues:"
		einfo "WARNING !! jackdbus does not use .jackdrc nor qjackctl settings"
	fi
}