updated ebuild, includes patch for `implicit declarations`

xournal-0.4.5-r2.ebuild (text/plain), 1.11 KB, created by Michael Weber (RETIRED) on 2010-10-07 22:30:15 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/xournal/xournal-0.4.5-r1.ebuild,v 1.3 2010/02/10 14:26:42 ssuominen Exp $

EAPI=2

inherit eutils

DESCRIPTION="Xournal is an application for notetaking, sketching, and keeping a journal using a stylus."
HOMEPAGE="http://xournal.sourceforge.net/"

SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pdf doc"

CDEPEND=">=app-text/poppler-0.12.3-r3[cairo]
	dev-libs/glib
	>=gnome-base/libgnomecanvas-2.4
	>=x11-libs/gtk+-2.10
	x11-libs/libX11"
RDEPEND="${CDEPEND}
	pdf? ( 
		>=app-text/poppler-0.12.3-r3[utils] 
		app-text/ghostscript-gpl 
	)"
DEPEND="${CDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

src_prepare() {
	epatch "${FILESDIR}"/${P}-xoprint-len.patch #bug 287701
	epatch "${FILESDIR}"/${P}-includes.patch

	export CPPFLAGS="${CPPFLAGS} -DHAVE_UNISTD_H"
}

src_install() {
	emake DESTDIR="${D}" install desktop-install || die

	dodoc ChangeLog AUTHORS README || die
	if use doc ; then
		dohtml -r html-doc/* || die
	fi
}