x11-libs/libva/libva-1.0.1.ebuild

libva-1.0.1.ebuild (text/plain), 913 bytes, created by Samuli Suominen (RETIRED) on 2010-02-17 11:24:39 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit autotools multilib

DESCRIPTION="Video Acceleration API"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/vaapi"
SRC_URI="http://cgit.freedesktop.org/libva/snapshot/${P}.tar.bz2"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="video_cards_dummy video_cards_intel"

RDEPEND="x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXfixes"
DEPEND="${RDEPEND}
	virtual/os-headers
	x11-proto/xproto
	>=x11-libs/libdrm-2.4
	dev-util/pkgconfig"

src_prepare() {
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable video_cards_dummy dummy-driver) \
		$(use_enable video_cards_intel i965-driver) \
		--disable-dependency-tracking
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodir /usr/$(get_libdir)/libva
	mv -vf "${D}"/usr/bin/test_* "${D}"/usr/$(get_libdir)/libva
}