new ebuild

gaupol-0.15.ebuild (text/plain), 1.26 KB, created by David Watzke on 2010-02-10 21:16:22 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit distutils fdo-mime gnome2-utils versionator

MY_PR=$(get_version_component_range 1-2)

DESCRIPTION="Gaupol is a subtitle editor for text-based subtitles."
HOMEPAGE="http://home.gna.org/gaupol"
SRC_URI="http://download.gna.org/${PN}/${MY_PR}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="spell"

RDEPEND=">=dev-lang/python-2.5.1
		<dev-lang/python-3
		>=dev-python/pygtk-2.12
		dev-python/chardet
		spell? ( >=dev-python/pyenchant-1.1.3
			app-text/iso-codes )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	dev-util/intltool"

DOCS="AUTHORS ChangeLog CREDITS NEWS TODO README"

src_compile() {
	addpredict /root/.gconf
	addpredict /root/.gconfd
	distutils_src_compile
}

pkg_postinst() {
	distutils_pkg_postinst
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	elog "Previewing support needs MPlayer or VLC."

	if use spell; then
		elog "Additionally, spell-checking requires a dictionary, any of"
		elog "Aspell/Pspell, Ispell, MySpell, Uspell, Hspell or AppleSpell."
	fi
}

pkg_postrm() {
	distutils_pkg_postrm
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}