ploticus-2.41.ebuild

ploticus-2.41.ebuild (text/plain), 3.65 KB, created by Markus Peloquin on 2010-01-06 02:03:22 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI="2"

inherit eutils toolchain-funcs

MY_P=pl${PV/.}src

S=${WORKDIR}/${MY_P}
DESCRIPTION="A command line application for producing graphs and charts"
HOMEPAGE="http://ploticus.sourceforge.net"
SRC_URI="mirror://sourceforge/ploticus/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT=0
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="gd flash nls svg svgz truetype X"
DEPEND="media-libs/libpng
	gd? ( >=media-libs/gd-1.84[jpeg,png] media-libs/jpeg )
	flash? ( =media-libs/ming-0.2a )
	truetype? ( =media-libs/freetype-2* )
	X? ( x11-libs/libX11 )
	!dev-lang/swi-prolog"

src_prepare() {
	# Fixes a problem with NOX11.
	# Changes the install directory and comments all flash and gd-related
	# options. (These options will be selectively uncommented later.)
	epatch ${FILESDIR}/${MY_P}.patch
}

src_compile() {
	cd src
	# ploticus may be compiled using the external libgd, a libgd provided with
	# the package, or no gd support at all.

	local MO=""
	if useq gd; then
		# PNG and JPEG are supported by default.
		GD18LIBS="-lgd -lpng -lz -ljpeg"
		# Note that truetype works only with the external gd lib.
		if useq truetype; then
			GD18LIBS="${GD18LIBS} -lfreetype"
			MO="${MO} GDFREETYPE=-DGDFREETYPE"
		fi
		# Set the graphics formats support.
		# Use the external libgd.
		MO="${MO} ZFLAG=-DWZ GD18H= GD16H="
		TARGET0="EXE=pl plgd18"
		TARGET1="EXE=plpng plpng"
		GD16LIBS="${GD18LIBS}"
		GD18LIBS="${GD18LIBS}"

	else
		# No support for libgd at all.
		# Note that gif and truetype do not work without gd.
		EXE=plnogd
		MO="${MO} NOGD=-DNOGD"
		TARGET0="EXE=plnogd plnogd"
		GD16LIBS=
		GD18LIBS=
	fi

	# Support for non-roman alphabets and collation.
	if useq nls; then
		MO="${MO} LOCALEOBJ=localef.o LOCALE_FLAG=-DLOCALE"
	fi

	# Support for compressed or uncompressed svg. svgz implies svg. If the
	# external gd library is used, the svgz format will always be available if
	# ploticus was compiled with support for svg (even if the svgz flag was not
	# specified and even if the -svgz flag was used).
	if useq svgz; then
		MO="${MO} ZLIB=-lz ZFLAG=-DWZ"
	elif ! useq svg; then
		MO="${MO} NOSVG=-DNOSVG"
	fi

	# Support for X11 output.
	if useq X; then
		XOBJ="x11.o interact.o"
		MO="${MO} XLIBS=-lX11"
	else
		XOBJ=
		MO="${MO} NOX11=-DNOX11"
	fi

	# Support for Flash output.
	if useq flash; then
		MO="${MO} MING=-lming"
	else
		MO="${MO} NOSWF=-DNOSWF"
	fi

	emake "CC=$(tc-getCC)" ${MO} XOBJ="${XOBJ}" GD18LIBS="${GD18LIBS}" \
		PREFABS_DIR=/usr/share/ploticus/prefabs ${TARGET0} || die
	if [ -n "${TARGET1}" ]; then
		emake "CC=$(tc-getCC)" ${MO} XOBJ="${XOBJ}" GD16LIBS="${GD16LIBS}" \
			PREFABS_DIR=/usr/share/ploticus/prefabs ${TARGET1} || die
	fi

	einfo "Compiling C API library"

	emake clean || die "Clean Failed!"
	emake "CC=$(tc-getCC)" NOSVG=-DNOSVG NOSWF=-DNOSWF NOX11=-DNOX11 \
		LIBEXT=a ARCOM="ar r" \
		-f Makefile libploticus-static || die "API make failed!"
}

src_test() {
	cd ${S}/pltestsuite
	export PATH="${S}/src:${PATH}"
	#sed -i -e "s:PL=.*:PL=${S}/src/pl:" run_script_test
	local TESTS="gif png jpeg eps"
	useq svg && TESTS="${TESTS} svg"
	useq svgz && TESTS="${TESTS} svgz"
	for TEST in ${TESTS};
	do
		echo "Testing ${TEST}"
		echo -e "${TEST}\n" | ./run_script_test
		cat Diag.out
	done
}

src_install() {
	dodoc README || die
	cd ${S}/src
	mkdir -p ${D}usr/bin
	if useq gd; then
		EXE="pl plpng"
	else
		EXE=pl
	fi
	emake INSTALLBIN=${D}usr/bin EXE="${EXE}" install || die

	dolib ${S}/src/libploticus.a

	PL_TARGET=/usr/share/${PN}
	insinto ${PL_TARGET}/prefabs
	doins ${S}/prefabs/*
	insinto ${PL_TARGET}/testsuite
	doins ${S}/pltestsuite/*
	insinto /usr/include
	doins ${S}/src/pl.h ${S}/src/plg.h
}