btanks-0.5.4740.ebuild

btanks-0.5.4740.ebuild (text/plain), 1.51 KB, created by Paul Bredbury on 2007-08-20 18:16:21 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DESCRIPTION="Fast 2D tank arcade game with multiplayer and split-screen modes"
HOMEPAGE="http://btanks.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="debug linguas_fr linguas_ru"

RDEPEND=">=dev-libs/libsigc++-2.0
	dev-libs/expat
	>=media-libs/libsdl-1.2.10
	media-libs/libvorbis
	media-libs/sdl-image
	media-libs/sdl-ttf
	media-libs/openal
	media-libs/freealut"
DEPEND="${RDEPEND}
	dev-util/scons"

dir=${GAMES_DATADIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	local lang
	for lang in fr ru ; do
		if ! use linguas_${lang} ; then
			rm -f README-${lang}.txt
		fi
	done
}

src_compile() {
	local buildmode="release"
	if use debug ; then
		buildmode="debug"
	fi

	scons \
		mode=${buildmode} \
		prefix=/usr \
		resources_dir="${dir}" \
		|| die "scons"
}

src_install() {
	local libdir="$(games_get_libdir)/${PN}"

	newgamesbin bt ${PN}.bin || die "newgamesbin"

	exeinto "${libdir}"
	doexe lib{mrt,bt,sdlx}.so || die "doexe libs"

	# Should go in libdir also, but is tricky to change program code
	exeinto "${dir}"
	doexe libbt_objects.so || die "doexe libbt_objects.so"

	insinto "${dir}"
	doins -r data || die "doins data"

	newicon src/bt.xpm ${PN}.xpm || die "newicon"
	games_make_wrapper ${PN} ${PN}.bin "${dir}" "${libdir}"
	make_desktop_entry ${PN} "Battle Tanks" ${PN}.xpm

	dodoc *.txt ChangeLog

	prepgamesdirs
}