updated 0.12.1 ebuild w/ python/java/tcltk/USB/userland support

pilot-link-0.12.1.ebuild (text/plain), 2.58 KB, created by Hans Meine on 2007-02-03 22:41:58 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/pilot-link/pilot-link-0.11.8-r1.ebuild,v 1.18 2007/01/11 18:19:24 gustavoz Exp $

inherit perl-module eutils

DESCRIPTION="suite of tools for moving data between a Palm device and a desktop"
HOMEPAGE="http://www.pilot-link.org/"
SRC_URI="http://pilot-link.org/source/${P}.tar.bz2"

LICENSE="|| ( GPL-2 LGPL-2 )"
SLOT="0"
KEYWORDS="alpha amd64 ia64 ppc sparc x86"
IUSE="usb perl java tcl tk python png readline"

DEPEND="virtual/libc
	sys-libs/ncurses
	usb? ( dev-libs/libusb )
	perl? ( dev-lang/perl )
	java? ( virtual/jre )
	tcl? ( dev-lang/tcl dev-tcltk/itcl
		tk? ( dev-lang/tk ) )
	python? ( dev-lang/python )
	png? ( media-libs/libpng )
	readline? ( sys-libs/readline )"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# cf. bug #63024, disabled because it did not seem to be needed
	# here [Hans Meine]
	# use java && epatch ${FILESDIR}/${P}-java_fPIC_fix.patch

	# sandboxed python install (Gentoo-specific patch)
	use python && epatch ${FILESDIR}/${P}-python_destdir.patch
	
	# those were send to the upstream mailing-list:
	# fix broken configure --with-python
	use python && epatch ${FILESDIR}/${P}-python_configure.patch
	# sandboxed java install
	use java && epatch ${FILESDIR}/${P}-java_install_destdir.patch
}

src_compile() {
	# should a local "noconduits" use flag be added? [Hans Meine]
	local myconf="--enable-conduits --includedir=/usr/include/libpisock"

	use usb \
		&& myconf="${myconf} --enable-libusb" \
		|| myconf="${myconf} --disable-libusb"

	use java \
		&& myconf="${myconf} --with-java=yes" \
		|| myconf="${myconf} --with-java=no"

	use perl \
		&& myconf="${myconf} --with-perl=yes" \
		|| myconf="${myconf} --with-perl=no"

	use python \
		&& myconf="${myconf} --with-python=yes" \
		|| myconf="${myconf} --with-python=no"

	if use tcl; then
		myconf="${myconf} --with-tcl=/usr/lib --with-itcl=yes"

		use tk \
			&& myconf="${myconf} --with-tk=yes" \
			|| myconf="${myconf} --with-tk=no"
	else
		myconf="${myconf} --with-tcl=no --with-itcl=no --with-tk=no"
	fi

	use png && myconf="${myconf} --with-libpng=/usr"

	use readline \
		&& myconf="${myconf} --with-readline=yes" \
		|| myconf="${myconf} --with-readline=no"

	econf ${myconf} || die
	# java fails w/emake
	make || die

	if use perl ; then
		cd ${S}/bindings/Perl
		perl-module_src_prep
		perl-module_src_compile
	fi
}

src_install() {
	make DESTDIR=${D} install || die

	dodoc ChangeLog README doc/README* doc/TODO NEWS AUTHORS

	if use perl ; then
		cd ${S}/bindings/Perl
		perl-module_src_install
	fi
}