quake1-textures-20060722.ebuild

quake1-textures-20060722.ebuild (text/plain), 1.31 KB, created by Paul Bredbury on 2006-07-23 15:28:50 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/quake1-textures/quake1-textures-20050820.ebuild,v 1.1 2006/06/19 20:28:38 wolf31o2 Exp $

inherit eutils games

MY_SKINS="SKINSbmodels-48files-4-23-05.zip"
MY_TEXTURES="qrp-textures-549files-7-22-06.zip"

DESCRIPTION="Collection of graphical improvements for Quake 1"
HOMEPAGE="http://facelift.quakedev.com/"
SRC_URI="http://facelift.quakedev.com/download/${MY_SKINS}
	http://facelift.quakedev.com/download/${MY_TEXTURES}
	http://files.quakeonline.net/textures/qrp/${MY_TEXTURES}"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

RDEPEND=""
DEPEND="app-arch/unzip"

S=${WORKDIR}
dir=${GAMES_DATADIR}/quake1

src_unpack() {
	unpack ${A}

	# Show the "retexturing project" words at the very start of a new game
	mv -f quake-QRP.tga textures/quake.tga

	# Move the skin textures to join the others
	mv *.tga textures
}

src_install() {
	insinto "${dir}"/id1
	doins -r textures \
		|| die "doins textures failed"

	# Set up symlink, for the demo levels to include the textures
	dosym "${dir}/id1/textures" "${dir}/demo/textures"

	dodoc *.txt

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "Use a Quake 1 client (e.g. darkplaces) to take advantage of these."
	echo
}