aufs-sources-4.13.3.ebuild (based on git commit)

aufs-sources-4.13.3.ebuild (text/plain), 2.13 KB, created by Bernd Buschinski on 2017-09-24 14:23:32 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

ETYPE="sources"
K_WANT_GENPATCHES="base extras experimental"
K_GENPATCHES_VER="5"
UNIPATCH_STRICTORDER=1
inherit kernel-2 eutils readme.gentoo-r1

EGIT_COMMIT="a65733673035a7054b0d5e6c2d834fe110c74ed2"
AUFS_ARCHIVE="aufs4-standalone-${P}.tar.gz"
AUFS_URI="https://github.com/sfjro/aufs4-standalone/archive/${EGIT_COMMIT}.tar.gz -> ${AUFS_ARCHIVE}"
AUFS_DIR="${WORKDIR}/aufs4-standalone-${EGIT_COMMIT}"

KEYWORDS="~amd64 ~x86"
HOMEPAGE="https://dev.gentoo.org/~mpagano/genpatches http://aufs.sourceforge.net/"
IUSE="experimental module vanilla"

DESCRIPTION="Full sources including the Gentoo patchset for the linux kernel tree and aufs4 support"
SRC_URI="
	${KERNEL_URI}
	${ARCH_URI}
	${AUFS_URI}
	!vanilla? ( ${GENPATCHES_URI} )
	"

PDEPEND="=sys-fs/aufs-util-4*"

README_GENTOO_SUFFIX="-r1"

src_unpack() {
	detect_version
	detect_arch
	if use vanilla; then
		unset UNIPATCH_LIST_GENPATCHES UNIPATCH_LIST_DEFAULT
		ewarn "You are using USE=vanilla"
		ewarn "This will drop all support from the gentoo kernel security team"
	fi

	UNIPATCH_LIST="
		"${AUFS_DIR}"/aufs4-kbuild.patch
		"${AUFS_DIR}"/aufs4-base.patch
		"${AUFS_DIR}"/aufs4-mmap.patch"

	use module && UNIPATCH_LIST+=" "${AUFS_DIR}"/aufs4-standalone.patch"

	unpack ${AUFS_ARCHIVE}

	kernel-2_src_unpack
}

src_prepare() {
	kernel-2_src_prepare
	if ! use module; then
		sed -e 's:tristate:bool:g' -i "${AUFS_DIR}"/fs/aufs/Kconfig || die
	fi
	cp -f "${AUFS_DIR}"/include/uapi/linux/aufs_type.h include/uapi/linux/aufs_type.h || die
	cp -rf "${AUFS_DIR}"/{Documentation,fs} . || die
}

src_install() {
	kernel-2_src_install
	dodoc "${AUFS_DIR}"/{aufs4-loopback,vfs-ino,tmpfs-idr}.patch
	docompress -x /usr/share/doc/${PF}/{aufs4-loopback,vfs-ino,tmpfs-idr}.patch
	readme.gentoo_create_doc
}

pkg_postinst() {
	kernel-2_pkg_postinst
	einfo "For more info on this patchset, and how to report problems, see:"
	einfo "${HOMEPAGE}"
	has_version sys-fs/aufs-util || \
		elog "In order to use aufs FS you need to install sys-fs/aufs-util"

	readme.gentoo_print_elog
}

pkg_postrm() {
	kernel-2_pkg_postrm
}