mangband-1.1.3.ebuild with epatch_user added

mangband-1.1.3.ebuild (text/plain), 1.81 KB, created by flambard on 2016-05-28 14:34:43 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5
inherit eutils games

DESCRIPTION="Online multiplayer real-time roguelike game, derived from Angband."
HOMEPAGE="http://www.mangband.org"
SRC_URI="http://www.mangband.org/download/${P}.tar.gz"

#RESTRICT=nomirror # for ebuild debugging

LICENSE="Moria"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="ncurses X sdl"

# Remove this once we hit MAngband 1.2:
S=${WORKDIR}/${P}/src

RDEPEND="
    ncurses? ( sys-libs/ncurses )
    X? ( x11-libs/libX11 )
    sdl? ( media-libs/libsdl )
    "
DEPEND="${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-strchr.patch \
	    "${FILESDIR}"/${P}-paths.patch
	epatch_user

}

src_configure() {
	egamesconf \
		--datadir="${GAMES_DATADIR_BASE}" \
		--with-setgid="${GAMES_GROUP}" \
		$(use_with ncurses gcu) \
		$(use_with X x11) \
		$(use_with sdl)
}

src_install() {
# Newer versions of MAngband have "make install", so we could use..
#    emake DESTDIR="${D}" install
#    dodoc NEWS README INSTALL AUTHORS
#..but not yet

	dogamesbin mangband mangclient

	# Read-only data
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r ${WORKDIR}/${P}/lib/{edit,file,help,text,xtra}

	# Server config
	insinto "${GAMES_SYSCONFDIR}"
	doins ${WORKDIR}/${P}/mangband.cfg

	# Read-write data
	insinto "${GAMES_STATEDIR}"/${PN}
	doins -r ${WORKDIR}/${P}/lib/{data,save,user}

	# Docs
	dodoc ${WORKDIR}/${P}/LICENSE

	# Finish up
	prepgamesdirs

	# All users in the games group need write permissions to
	# some important dirs
	fperms -R g+w "${GAMES_STATEDIR}"/${PN}/{data,save,user}
}

pkg_postinst() {
	echo
	elog "Make sure LibDir in either unset in ~/.mangrc either points to"
	elog " ${GAMES_DATADIR}/${PN} "
	elog "Server binary is called 'mangband', client binary is 'mangclient'."
	echo

	games_pkg_postinst
}