katawa-shoujo-1.3.ebuild

katawa-shoujo-1.3.ebuild (text/plain), 1.99 KB, created by Pavel Volkov on 2015-04-04 17:50:30 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-misc/katawa-shoujo/katawa-shoujo-1.2-r2.ebuild,v 1.1 2014/11/07 22:59:53 hasufell Exp $

EAPI=5

inherit eutils gnome2-utils games

DESCRIPTION="Bishoujo-style visual novel set in the fictional Yamaku High School for disabled children"
HOMEPAGE="http://katawa-shoujo.com/"
SRC_URI="http://dl.katawa-shoujo.com/gold_1.3/%5b4ls%5d_katawa_shoujo_1.3-%5blinux-x86%5d%5bFCF758CC%5d.tar.bz2 -> ${P}.tar.bz2
	http://dev.gentoo.org/~hasufell/distfiles/katawa-shoujo-48.png
	http://dev.gentoo.org/~hasufell/distfiles/katawa-shoujo-256.png"

LICENSE="CC-BY-NC-ND-3.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc system-renpy"

renpy_slot="6.16"
RDEPEND="system-renpy? ( games-engines/renpy:$renpy_slot )"

QA_PREBUILT="${GAMES_PREFIX_OPT}/${PN}/lib/*"

S="${WORKDIR}/Katawa Shoujo-${PV}-linux"

src_install() {
	if use system-renpy ; then
		insinto "${GAMES_DATADIR}/${PN}"
		doins -r game/.
		games_make_wrapper ${PN} "renpy-$renpy_slot '${GAMES_DATADIR}/${PN}'"
	else
		insinto "${GAMES_PREFIX_OPT}"/${PN}
		doins -r game lib localizations renpy "Katawa Shoujo.py" "Katawa Shoujo.sh"
		games_make_wrapper ${PN} "./Katawa\ Shoujo.sh" "${GAMES_PREFIX_OPT}/${PN}"
		fperms +x "${GAMES_PREFIX_OPT}/${PN}"/lib/linux-i686/python \
			"${GAMES_PREFIX_OPT}/${PN}"/lib/linux-x86_64/python \
			"${GAMES_PREFIX_OPT}/${PN}"/lib/linux-i686/Katawa\ Shoujo \
			"${GAMES_PREFIX_OPT}/${PN}"/lib/linux-x86_64/Katawa\ Shoujo \
			"${GAMES_PREFIX_OPT}/${PN}/Katawa Shoujo.sh" \
			"${GAMES_PREFIX_OPT}/${PN}/Katawa Shoujo.py"
	fi

	local i
	for i in 48 256; do
		newicon -s ${i} "${DISTDIR}"/${PN}-${i}.png ${PN}.png
	done

	make_desktop_entry ${PN} "Katawa Shoujo"

	if use doc ; then
		newdoc "Game Manual.pdf" manual.pdf
	fi

	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}