dev-python/dnspython-1.11.1-r1 ebuild proposal

dnspython-1.11.1-r1.ebuild (text/plain), 1.59 KB, created by Vincent-Xavier JUMEL on 2014-12-24 14:34:35 UTC

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/dnspython/dnspython-1.11.1.ebuild,v 1.9 2014/09/14 07:27:45 ago Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_3,3_4} )

inherit distutils-r1
MY_PN3="dnspython3"
MY_WK3="${WORKDIR}3"

DESCRIPTION="DNS toolkit for Python"
HOMEPAGE="http://www.dnspython.org/ http://pypi.python.org/pypi/dnspython"
SRC_URI="http://www.dnspython.org/kits/${PV}/${P}.tar.gz
http://www.dnspython.org/kits3/${PV}/${MY_PN3}-${PV}.tar.gz"

LICENSE="ISC"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
IUSE="examples test"

DEPEND="dev-python/pycrypto[${PYTHON_USEDEP}]"
RDEPEND="${DEPEND}"

DOCS=( ChangeLog README )

src_unpack() {
	unpack ${P}.tar.gz
	unpack ${MY_PN3}-${PV}.tar.gz
}

python_prepare_all() {
	use test && DISTUTILS_IN_SOURCE_BUILD=1
	distutils-r1_python_prepare_all
}

select_source() {
	if [[ ${EPYTHON} == python3* ]]; then
		cd "${WORKDIR}"/${MY_PN3}-${PV} || die
	else
		cd "${S}" || die
	fi
}

python_compile() {
>···select_source
>···distutils-r1_python_compile
}

python_test() {
	pushd "${BUILD_DIR}"/../tests &> /dev/null
	local test
	for test in *.py; do
		if ! "${PYTHON}" ${test}; then
			die "test $test failed under ${EPYTHON}"
		else
			einfo "test $test"
		fi
	done
	# make some order out of the output salad
	einfo "Testsuite passed under ${EPYTHON}"
}

python_install() {
	select_source
	use examples && local EXAMPLES=( examples/. )
	distutils-r1_python_install
}