ulogd-2.0.1.ebuild

ulogd-2.0.1-r2.ebuild (text/plain), 1.70 KB, created by Coacher on 2013-01-02 17:32:48 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit eutils user

DESCRIPTION="A userspace logging daemon for netfilter/iptables related logging"
HOMEPAGE="http://netfilter.org/projects/ulogd/index.html"
SRC_URI="http://ftp.netfilter.org/pub/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc mysql postgres dbi"

RDEPEND="net-firewall/iptables
	>=net-libs/libnfnetlink-1.0.1
	>=net-libs/libmnl-1.0.3
	>=net-libs/libnetfilter_acct-1.0.1
	>=net-libs/libnetfilter_conntrack-1.0.2
	>=net-libs/libnetfilter_log-1.0.0
	net-libs/libpcap
	dev-db/sqlite:3
	mysql? ( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	dbi? ( dev-db/libdbi )"

DEPEND="${RDEPEND}
	doc? (
			app-text/linuxdoc-tools
			app-text/texlive-core
		)"

src_configure() {
	econf \
		$(use_with mysql) \
		$(use_with postgres pgsql) \
		$(use_with dbi)
}

src_compile() {
	emake

	if use doc ; then
		# prevent access violations from generation of bitmap font files
		export VARTEXFONTS="${T}"/fonts
		emake -C doc
	fi
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc AUTHORS README doc/sqlite3.table

	if use doc ; then
		dohtml doc/ulogd.html
		dodoc doc/ulogd.dvi
		dodoc doc/ulogd.txt
		dodoc doc/ulogd.ps
	fi

	use mysql && dodoc doc/mysql-*.sql
	use postgres && dodoc doc/pgsql-*.sql

	insinto /etc
	doins ulogd.conf

	newinitd "${FILESDIR}/ulogd.init" ulogd

	insinto /etc/logrotate.d
	newins "${FILESDIR}/ulogd.logrotate" ulogd

	doman ulogd.8 || die
}

pkg_preinst() {
	enewgroup ulogd
	enewuser ulogd -1 -1 /var/log/ulogd ulogd
}

pkg_postinst() {
	chown root:ulogd "${ROOT}"/etc/ulogd.conf
	chmod 640        "${ROOT}"/etc/ulogd.conf
}