processing-1.0.1.ebuild

processing-1.0.1.ebuild (text/plain), 1.17 KB, created by MATSUU Takuto (RETIRED) on 2008-12-19 12:14:09 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="an open source programming language and environment for people who want to program images, animation, and sound"
HOMEPAGE="http://processing.org/"
SRC_URI="http://processing.org/download/${P}.tgz"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RESTRICT="strip"

RDEPEND=">=virtual/jdk-1.5
	x11-misc/xdg-utils
	amd64? (
		app-emulation/emul-linux-x86-soundlibs
		app-emulation/emul-linux-x86-xlibs
	)"

OPTDIR="/opt/${PN}"

QA_TEXTRELS="${OPTDIR:1}/java/lib/i386/motif21/libmawt.so
	${OPTDIR:1}/java/lib/i386/client/libjvm.so
	${OPTDIR:1}/java/lib/i386/libdeploy.so
	${OPTDIR:1}/java/lib/i386/server/libjvm.so"

QA_EXECSTACK="${OPTDIR:1}/libraries/serial/library/librxtxSerial.so"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i -e '/^browser.linux/s|mozilla|xdg-open|' lib/preferences.txt || die
}

src_install() {
	insinto "${OPTDIR}"
	cp -pPR * "${D}${OPTDIR}" || die
	make_wrapper ${PN} ./processing "${OPTDIR}" || die

	dodoc revisions.txt
	dohtml -r reference/*
	dosym /usr/share/doc/${PF}/html "${OPTDIR}"/reference
}