unreal-tournament-infiltration/unreal-tournament-infiltration-290.ebuild

unreal-tournament-infiltration-290.ebuild (text/plain), 2.15 KB, created by Paul Bredbury on 2007-05-18 10:29:29 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PV="29"
MY_PN="ut-inf"
# Manual downloads available at http://mirror.infgermany.de/
INF_SRC="ftp://infiles.sentrystudios.net/INF${MY_PV}"

DESCRIPTION="Realistic mod for Unreal Tournament"
HOMEPAGE="http://infiltration.sentrystudios.net/"
SRC_URI="${INF_SRC}/TBT_DesertStorm.zip
	${INF_SRC}/INF${MY_PV}man_full.zip
	${INF_SRC}/INF${MY_PV}BonusPack_manual.zip
	${INF_SRC}/INF_MiniUziFix.zip
	${INF_SRC}/INF_PickupMenuFix.zip"

LICENSE="as-is"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE=""
RESTRICT="strip"

# From http://infiltration.sentrystudios.net/INFManual/install.html
# "Connection problems are known to exist in v436,
# so it is recommended to use v451."
RDEPEND="|| (
		>=games-fps/unreal-tournament-451
		>=games-fps/unreal-tournament-goty-451 )"
DEPEND="app-arch/unzip"

S=${WORKDIR}

src_unpack() {
	unpack ${A}

	find . -type f '(' -name '*.dll' -o -name '*.exe' ')' -delete

	# Linux-ize the ini file. Add PickupMenuFix hotfix.
	local ini="System/Infiltration.ini"
	sed -i "${ini}" \
		-e "s:GameRenderDevice=D3DDrv.D3DRenderDevice:GameRenderDevice=SDLGLDrv.SDLGLRenderDevice:" \
		-e "s:WindowedRenderDevice=SoftDrv.SoftwareRenderDevice:WindowedRenderDevice=SDLGLDrv.SDLGLRenderDevice:" \
		-e "s:RenderDevice=GlideDrv.GlideRenderDevice:RenderDevice=SDLGLDrv.SDLGLRenderDevice:" \
		-e "s:WinDrv.WindowsClient:SDLDrv.SDLClient:" \
		-e "s:Galaxy.GalaxyAudio:ALAudio.ALAudio:" \
		-e "s:UseDirectSound=True:UseDirectSound=False:" \
		-e "s:EffectsChannels=16:Channels=16:" \
		-e "s:UseSpatial=False:UseSpatial=True:" \
		-e "/ServerPackages=INF_cGear/a\ServerPackages=INF_PickupMenuFix" \
		|| die "sed ${ini}"
	edos2unix "${ini}" || die "edos2unix"
}

src_install() {
	local dir=${GAMES_PREFIX_OPT}/unreal-tournament
	local i="Infiltration"

	insinto "${dir}"
	doins -r * || die "doins failed"

	games_make_wrapper ${MY_PN} "ut -ini=${i}.ini -userini=${i}User.ini -log=${i}.log"
	make_desktop_entry ${MY_PN} "Unreal Tournament - ${i}" ut.xpm

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "To play ${P}, run:  ${MY_PN}"
	echo
}