Bug 459202 – app-emacs/emacs-w3m version 1.4.437_pre20110310 broken with emacs24

• Status: RESOLVED FIXED
• Product: Gentoo Linux

[Description Paul Fertser 2013-02-25 19:01:45 UTC]

This version is old and doesn't work properly with Emacs24, e.g. creating 2 tabs and switching between them doesn't behave as expected. Not having CVS version available in the portage makes it hard to test the really latest code.

The current CVS version seems to be working just fine.

Example ebuild to allow testing the latest version:
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emacs/emacs-w3m/emacs-w3m-1.4.437_pre20110310.ebuild,v 1.2 2011/07/08 10:55:43 ssuominen Exp $

EAPI=3

inherit elisp autotools cvs

DESCRIPTION="emacs-w3m is an interface program of w3m on Emacs"
HOMEPAGE="http://emacs-w3m.namazu.org"
ECVS_SERVER="cvs.namazu.org:/storage/cvsroot"
ECVS_MODULE="emacs-w3m"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="linguas_ja"

DEPEND="virtual/w3m"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}"
SITEFILE="70${PN}-gentoo.el"

src_prepare() {
	eautoreconf
}

# This is NOT redundant, elisp.eclass redefines src_configure
src_configure() {
	econf
}

src_compile() {
	emake all-en $(use linguas_ja && echo all-ja) || die "emake failed"
}

src_install() {
	emake lispdir="${ED}${SITELISP}/${PN}" \
		infodir="${ED}/usr/share/info" \
		ICONDIR="${ED}${SITEETC}/${PN}" \
		install-en $(use linguas_ja && echo install-ja) install-icons \
		|| die "emake install failed"

	elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
	dodoc ChangeLog* NEWS README
	use linguas_ja && dodoc BUGS.ja NEWS.ja README.ja
}

pkg_postinst() {
	elisp-site-regen
	einfo "Please see ${EPREFIX}/usr/share/doc/${PF}/README*"
	einfo
	elog "If you want to use the shimbun library, please emerge app-emacs/apel"
	elog "and app-emacs/flim."
}


Reproducible: Always

[Comment 1 Tom Wijsman (TomWij) (RETIRED) 2013-02-25 21:56:27 UTC]

Please use the attachment feature in the future, thank you. :)

[Comment 2 Ulrich Müller 2013-02-26 07:16:20 UTC]

+*emacs-w3m-1.4.513_pre20130204 (25 Feb 2013)
+
+  25 Feb 2013; Ulrich Müller <[e-mail]>
+  -emacs-w3m-1.4.417_pre20101104.ebuild, emacs-w3m-1.4.437_pre20110310.ebuild,
+  +emacs-w3m-1.4.513_pre20130204.ebuild:
+  New snapshot from CVS, fixes issues with Emacs 24, bug 459202. Remove old.
+  Specify LICENSE more precisely.
+

Thanks for reporting.