serverstats-0.7 ebuild

serverstats-0.7.ebuild (text/plain), 1.15 KB, created by Jakub Moc (RETIRED) on 2005-09-16 10:34:34 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit webapp depend.php

DESCRIPTION="serverstats is a rrdtool harvester and a lightweight replacement for cacti"
HOMEPAGE="http://www.webmasterpro.de/~ddanier/serverstats/"
SRC_URI="http://www.webmasterpro.de/~ddanier/serverstats/downloads/${P}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~x86"
IUSE=""

RDEPEND=">=net-analyzer/rrdtool-1.2
	virtual/cron"

need_php5

src_unpack() {
	unpack "${A}"
	cd "${S}"
	mv config.sample/ config/
}

src_install() {
	webapp_src_preinst

	einfo "Installing docs"
	dodoc doc/*.txt
	docinto examples
	newdoc sources/traffic/iptables.sample iptables-rules.sample
	newdoc sources/traffic/traffic.sh traffic.sh.sample
	rm -rf doc/ sources/traffic/
	rm -f INSTALL LICENSE sources/external/cacti/README

	einfo "Installing main files"
	cp -pPR . "${D}/${MY_HTDOCSDIR}"

	webapp_serverowned "${MY_HTDOCSDIR}"/graph

	cd "${D}/${MY_HTDOCSDIR}"
	local CONFFILE
	for CONFFILE in config/* ; do
	    webapp_configfile "${MY_HTDOCSDIR}/${CONFFILE}"
	done

	webapp_postinst_txt en ${FILESDIR}/postinstall-en.txt

	webapp_src_install
}