new ebuild script

firestarter-1.0.1-r2.ebuild (text/plain), 3.34 KB, created by richard ferguson on 2004-12-18 06:40:23 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/firestarter/firestarter-0.9.3.ebuild,v 1.4 2004/09/28 20:51:13 blubb Exp $

inherit eutils gnome2

DESCRIPTION="GUI for iptables firewall setup and monitor."
HOMEPAGE="http://firestarter.sf.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc ~alpha ~ppc64 ~amd64"
IUSE="nls"

RDEPEND=">=dev-libs/glib-2.4
    >=x11-libs/gtk+-2.4   
    >=gnome-base/gnome-vfs-2.6
	>=gnome-base/libgnomeui-2
	>=gnome-base/libgnome-2
    >=gnome-base/libglade-2.4
	dev-perl/XML-Parser
	net-firewall/iptables
	nls? ( sys-devel/gettext )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=dev-util/intltool-0.21"

pkg_setup() {
	G2CONF=$(use_enable nls)
	DOCS="AUTHORS ChangeLog CREDITS INSTALL README TODO"
}

src_unpack() {

	#patch in gentoo changes
	unpack ${A}
	cd ${S}
	epatch ${FILESDIR}/firestarter-1.0.1-gentoo.patch
}

src_install() { 

	export GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1
    make DESTDIR=${D} install || die "Error installing firestarter."

    # install pam file
    insinto /etc/pam.d/
    newins ${S}/firestarter.pam firestarter

    # install security console file
    insinto /etc/security/console.apps/
    newins ${S}/firestarter.console firestarter
		
    # copy in init script for daemon
    exeinto /etc/init.d/
    newexe ${FILESDIR}/firestarter.init firestarter
	
}

pkg_postinst() {

	# install gconf schemas
	export GCONF_CONFIG_SOURCE="$(gconftool-2 --get-default-source)"
	gconftool-2 --makefile-install-rule /etc/gconf/schemas/firestarter.schemas &>/dev/null
		
    einfo ""
    einfo "To start the firestarter configuration on boot,"
    einfo "you should add it to the default runlevel:"
    einfo ""
    einfo "rc-update add firestarter default"
    einfo ""
    einfo "To start the firestarter configuration on a per"
    einfo "interface basis, use the net postup hooks by"
    einfo "running: "
    einfo ""
	einfo "\"ebuild /var/db/pkg/net-firewall/${PF}/${PF}.ebuild config\""
    einfo ""
    
}

pkg_config() {
    einfo "Press ENTER to attach the firestarter postup hooks"
    einfo "into /etc/conf.d/net, or Control-C to abort now..."
    read

	cat >> /etc/conf.d/net <<EOF

###########################################
# Hook firestarter into network scripts

# Use to exclude interfaces from firestarter configuration
#exclude="eth0 eth1"

postup() {
       	if [[ \`echo \$exclude | grep \$1\` ]]; then
			return 0
	   	fi
		
		# Update external interface preference
		gconftool-2 --type string --set /apps/firestarter/firewall/ext_if "\$1"

		# Regenerate firestarter scripts
		/usr/bin/firestarter --generate-scripts

		# Start firewall
		/usr/bin/firestarter --start

		# Signal a userspace instance if available
		FSPID=\`pidof firestarter\`
		if [[ \$FSPID ]]; then
			kill -USR1 \$FSPID
		fi

		# Return 0 for success (ignored)
       	return 0
}

postdown() {
		if [[ \`echo \$exclude | grep \$1\` ]]; then
			return 0
		fi
		
		# Stop firewall
	   	/usr/bin/firestarter --stop
		
		# Signal a userspace instance if available
		FSPID=\`pidof firestarter\`
		if [[ \$FSPID ]]; then
			kill -USR1 \$FSPID
		fi

       	# Return 0 for success (ignored)
       	return 0
}

# End hook
###########################################
EOF

    einfo "/etc/conf.d/net Patched!"
}