openocd-9999.ebuild (use git, some USE flags and --enable-xxx tweak)

openocd-9999.ebuild (text/plain), 1.83 KB, created by Victor Tseng on 2009-12-07 23:10:16 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-embedded/openocd/openocd-9999.ebuild,v 1.6 2009/06/17 10:04:16 vapier Exp $

EAPI=2
EGIT_REPO_URI="git://repo.or.cz/${PN}.git"

inherit eutils
if [[ ${PV} == "9999" ]] ; then
	inherit git autotools
	KEYWORDS=""
	SRC_URI=""
else
	KEYWORDS="~x86"
	SRC_URI="mirror://berlios/${PN}/${P}.tar.gz"
fi

DESCRIPTION="OpenOCD - Open On-Chip Debugger"
HOMEPAGE="http://openocd.berlios.de/web/"

LICENSE="GPL-2"
SLOT="0"
IUSE="presto ft2232 libftdi parport-giveio"
RESTRICT="strip" # includes non-native binaries

# libftd2xx is the default because it is reported to work better.
DEPEND="dev-libs/libusb
	presto? ( || (
		libftdi? ( dev-embedded/libftdi )
		dev-embedded/libftd2xx )
	)
	ft2232? ( || (
		libftdi? ( dev-embedded/libftdi )
		dev-embedded/libftd2xx )
	)"
RDEPEND="${DEPEND}"

src_unpack() {
	if [[ ${PV} == "9999" ]] ; then
		git_src_unpack
		cd "${S}"
		eautoreconf
	else
		unpack ${A}
	fi
}

src_compile() {
	econf \
		--enable-maintainer-mode \
		--disable-werror \
		--enable-parport \
		--enable-parport-ppdev \
		--enable-amtjtagaccel \
		--enable-ep93xx \
		--enable-at91rm9200 \
		--enable-gw16012 \
		--enable-usbprog \
		--enable-oocd_trace \
		--enable-jlink \
		--enable-vsllink \
		--enable-rlink \
		--enable-arm-jtag-ew \
		$(use_enable parport-giveio) \
		$(use ft2232 && use_enable libftdi ft2232_libftdi) \
		$(use ft2232 && use_enable !libftdi ft2232_ftd2xx) \
		$(use presto && use_enable libftdi presto_libftdi) \
		$(use presto && use_enable !libftdi presto_ftd2xx) \
		|| die "Error in econf"
		#$(use_enable ioutil) \
		#$(use_enable httpd) \
	emake || die "Error in emake!"
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS README TODO
	prepstrip "${D}"/usr/bin
}