The ebuild for nil

nil-cvs-0.ebuild (text/plain), 1.17 KB, created by Aynjell Starwing on 2005-02-18 15:01:43 UTC

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games cvs

S="${WORKDIR}/${PN/-cvs}"
DESCRIPTION="Nil isn't Liero (Liero clone)"
HOMEPAGE="http://nil.sourceforge.net/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND="virtual/x11
	>=media-libs/libsdl-1.2.5
	>=media-libs/sdl-image-1.2.2
	>=media-libs/sdl-mixer-1.2.5
	>=media-libs/sdl-ttf-2.0.5
	media-libs/freetype
	sys-libs/zlib"
DEPEND="${RDEPEND}
	dev-lang/python"

ECVS_SERVER="cvs.sourceforge.net:/cvsroot/nil"
ECVS_MODULE="nil"
ECVS_USER="anonymous"
ECVS_PASS=""

src_unpack() {
	cvs_src_unpack
	cd ${S}
	sed -i \
		-e "s/cd src.*/\$(MAKE) -C src \$(@)/" Makefile \
			|| die "sed Makefile failed"
	sed -i \
		-e "s:-Wall -O0 -g:${CXXFLAGS}:" src/Makefile \
			|| die "sed src/Makefile failed"
}

src_compile() {
	emake || die "emake failed"
	cd utils/lumper
	chmod a+x makelump.sh lumpdump.py
	./makelump.sh
}

src_install() {
	dogamesbin src/nil || die "dogamesbin failed"
	insinto "${GAMES_DATADIR}/nil"
	doins default.lump || die "doins failed"
	dodoc docs/{HOWTO,TODO} AUTHORS ChangeLog  || die "dodoc failed"
	prepgamesdirs
}