Bug 643072 – sys-process/htop: please add lm-sensors support

• Status: RESOLVED FIXED
• Product: Gentoo Linux

[Description Michael T. Kloos 2018-01-02 05:06:21 UTC]

Created attachment 512686 [details]
added_changed_files.tar.gz

Add support in htop for lm_sensors by conditionally applying the temperature patch in the ebuild.  This is done by the addition of the use flag "lm_sensors".  Attached are the changed/new files to apply this feature from my own local testing overlay.  Please note, I am new to this and haven't modified the ebuild beyond the lines strictly necessary to implement this feature.  The patch is copied off the Arch AUR.  Currently this applies to htop version "2.0.2".

[Comment 1 Michael T. Kloos 2018-01-02 08:07:47 UTC]

Additional preliminary testing reveals a build-time dependency on python when using the sensors patch.

[Comment 2 Denis Descheneaux 2018-02-05 21:35:45 UTC]

Is this available yet for the new 2.1.0 version?

[Comment 3 Denis Descheneaux 2018-02-12 16:50:52 UTC]

New patch for 2.1.0 here:
https://aur.archlinux.org/packages/htop-temperature/

save in ./files/htop-2.1.0-temperature.patch

also copy in your local overlay the added patch in the ./files folder:
htop-2.1.0-sysmacros.patch

and modified ebuild: htop-2.1.0.ebuild

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit autotools linux-info

DESCRIPTION="interactive process viewer"
HOMEPAGE="http://hisham.hm/htop/"
SRC_URI="http://hisham.hm/htop/releases/${PV}/${P}.tar.gz"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux"
IUSE="kernel_FreeBSD kernel_linux openvz unicode vserver  lm_sensors"

RDEPEND="sys-libs/ncurses:0=[unicode?]
	lm_sensors? ( sys-apps/lm_sensors )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS=( ChangeLog README )

CONFIG_CHECK="~TASKSTATS ~TASK_XACCT ~TASK_IO_ACCOUNTING ~CGROUPS"

PATCHES=(
	"${FILESDIR}/${P}-sysmacros.patch"
)

pkg_setup() {
	if ! has_version sys-process/lsof; then
		ewarn "To use lsof features in htop(what processes are accessing"
		ewarn "what files), you must have sys-process/lsof installed."
	fi

	linux-info_pkg_setup
}

src_prepare() {
	rm missing || die

	if use lm_sensors ; then
		eapply "${FILESDIR}/${P}-temperature.patch"
	fi

	default
	eautoreconf
}

src_configure() {
	[[ $CBUILD != $CHOST ]] && export ac_cv_file__proc_{meminfo,stat}=yes #328971

	local myeconfargs=(
		# fails to build against recent hwloc versions
		--disable-hwloc
		--enable-taskstats
		$(use_enable kernel_linux cgroup)
		$(use_enable kernel_linux linux-affinity)
		$(use_enable openvz)
		$(use_enable unicode)
		$(use_enable vserver)
	)
	econf ${myeconfargs[@]}
}

[Comment 4 Lars Wendler (Polynomial-C) (RETIRED) 2022-01-14 09:00:44 UTC]

htop-3.x ebuilds have lm_sensors support.