netscape-flash-9.0.21.55.ebuild

netscape-flash-9.0.21.55.ebuild (text/plain), 1017 bytes, created by Paul Bredbury on 2006-10-18 23:11:30 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit nsplugins

BETA_PV="101806"

DESCRIPTION="Macromedia Shockwave Flash Player"
HOMEPAGE="http://www.macromedia.com/"
SRC_URI="http://download.macromedia.com/pub/labs/flashplayer9_update/FP9_plugin_beta_${BETA_PV}.tar.gz"

LICENSE="Macromedia"
SLOT="0"
KEYWORDS="~amd64 -ppc -sparc ~x86"
IUSE=""
RESTRICT="strip"

DEPEND="!net-www/gplflash"
RDEPEND="${DEPEND}
	amd64? ( app-emulation/emul-linux-x86-baselibs
			 app-emulation/emul-linux-x86-xlibs )"

QA_TEXTRELS="opt/netscape/plugins/libflashplayer.so"

S=${WORKDIR}/flash-player-plugin-${PV}

pkg_setup() {
	# This is a binary x86 package => ABI=x86
	# Please keep this in future versions
	# Danny van Dyk <[e-mail]> 2005/03/26
	has_multilib_profile && ABI="x86"
}

src_install() {
	exeinto /opt/netscape/plugins
	doexe libflashplayer.so || die

	inst_plugin /opt/netscape/plugins/libflashplayer.so || die

	dodoc readme.txt
}