ebuild with patches from debian experimental ported

vdr-vdrrip-0.3.0-r3.ebuild (text/plain), 2.20 KB, created by E. Scaglione on 2006-10-06 00:06:48 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-vdrrip/vdr-vdrrip-0.3.0-r3.ebuild,v 1.5 2006/06/15 09:59:54 zzam Exp $

inherit vdr-plugin eutils

RESTRICT="nomirror"
DESCRIPTION="Video Disk Recorder vdrrip PlugIn"
HOMEPAGE="http://www.a-land.de/"
SRC_URI="http://www.a-land.de/vdr-${VDRPLUGIN}-${PV}.tgz
		http://www.a-land.de/queuehandler-fixed-0.3.0.sh
		mirror://vdrfiles/${PN}/vdr-${VDRPLUGIN}-${PV}.tgz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~x86 ~amd64"
IUSE=""

DEPEND=">=media-video/vdr-1.2.0"
RDEPEND=">=media-video/mplayer-1.0_pre8
		sys-process/procps
		sys-apps/util-linux"
# media-video/vdrsync seems to be optional

src_unpack() {
	vdr-plugin_src_unpack
	cp ${DISTDIR}/queuehandler-fixed-0.3.0.sh ${S}/scripts/queuehandler.sh

	if
	has_version ">=media-video/vdr-1.3.7" ;
	then
		einfo "applying VDR > 1.3.6 patch"
		epatch ${FILESDIR}/vdrrip-0.3.0-1.3.7.diff
		epatch ${FILESDIR}/mplayercmd.diff
		epatch ${FILESDIR}/maketempdir.diff
		epatch ${FILESDIR}/greppid2.diff
		epatch ${FILESDIR}/detectlength.diff
		epatch ${FILESDIR}/fix-ogm-ac3-vdrsync-dev.diff
	fi

	einfo "Patching queuehandler.sh.conf for gentoo-needs..."
	cd ${S}
	sed -e "s,/usr/local/bin/,/usr/bin/," \
		-e 's,/usr/bin/mencoder_ac3,/usr/bin/mencoder,' \
		-e 's,/usr/bin/mplayer_ac3,/usr/bin/mplayer,' \
		-i scripts/queuehandler.sh.conf

	sed -e 's,scriptdir=`dirname $0`,scriptdir=/etc/conf.d,' \
		-e 's,nice -+19,nice -n 19,' \
		-i scripts/queuehandler.sh
}

src_install() {
	vdr-plugin_src_install

	# save config files
	insinto /etc/conf.d
	newins scripts/queuehandler.sh.conf vdrrip-qh.conf
	newins ${FILESDIR}/vdrrip-qh.conf vdrrip-qh
	# add start script
	exeinto /etc/init.d
	doexe ${FILESDIR}/vdrrip-qh
	# save in bin
	newbin scripts/queuehandler.sh vdrrip-qh
}

pkg_postinst() {
	vdr-plugin_pkg_postinst

	einfo "You should have a look at this files:"
	einfo
	einfo "* /etc/conf.d/vdr.$VDRPLUGIN"
	einfo "* /etc/conf.d/vdrrip-qh.conf"
	einfo
	einfo "Use vdrrip-qh to start the vdrrip queue handler."
	einfo "You can also run 'rc-update add /etc/init.d/vdrrip-qh default'. to"
	einfo "let vdrrip-qh start automaticly when the system starts."
}