The actual ebuild for cdogs-sdl (cdogs-sdl-0.3.ebuild)

cdogs-sdl-0.3.ebuild (text/plain), 1.55 KB, created by Lucas Martin-King on 2006-10-04 02:56:33 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils
inherit games

DESCRIPTION="C-Dogs SDL is a port of the classic DOS arcade game, C-Dogs."
HOMEPAGE="http://lmk.is.dreaming.org/hacks/cdogs"

CDOGS_DATA="cdogs-data-2006-08-16"
SRC_URI="
		http://icculus.org/cdogs-sdl/files/src/${P}.tar.bz2
		http://icculus.org/cdogs-sdl/files/data/${CDOGS_DATA}.tar.bz2
		"
LICENSE="GPL-2"
SLOT="0"

KEYWORDS="~x86 ~amd64 ~ppc"

DEPEND="
	>=media-libs/libsdl-1.2.0
	>=media-libs/sdl-mixer-1.2.0
"

S="${WORKDIR}/${P}/src"

src_unpack () {
	unpack ${A}
	S="${WORKDIR}/${P}/src"
	cd "${S}"

	sed -i \
		-e "s/CF_OPTIMISE.*+= -O2//" \
		Makefile || die "sed failed"
}

src_compile() {
	emake \
		I_AM_CONFIGURED=yes \
		SYSTEM=\"linux\" \
		PREFIX=\"${GAMES_PREFIX}\" \
		BINDIR=\"${GAMES_BINDIR}\" \
		DATADIR=\"${GAMES_DATADIR}/${PN}\" \
		DESTDIR=\"${D}\" \
		cdogs || die "emake failed"
}

# We do all this manually, since the install script is broken =/
src_install() {
	einfo "Installing docs..."
	cd "${WORKDIR}/${P}/doc" &&
	dodoc AUTHORS COPYING ChangeLog README \
			README_DATA TODO original_readme.txt

	einfo "Installing cdogs binary..."
	cd "${S}" && dogamesbin cdogs || die "couldn't install binary"

	einfo "Installing data files..."
	dodir "${GAMES_DATADIR}/${PN}"
	insinto "${GAMES_DATADIR}/${PN}"
	cd "${WORKDIR}/${CDOGS_DATA}"
	doins cdogs_icon.png

	for dir in graphics missions sounds ; do
		insinto "${GAMES_DATADIR}/${PN}/$dir"
		doins $dir/* || die "couldn't install $dir"
	done

	prepgamesdirs
}