games-arcade/tecnoballz/tecnoballz-9999.ebuild

tecnoballz-9999.ebuild (text/plain), 2.11 KB, created by Chris Gianelloni (RETIRED) on 2006-09-29 12:11:43 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools cvs eutils games

ECVS_SERVER="cvs.${PN}.berlios.de:/cvsroot/${PN}"
ECVS_MODULE=${PN}

DESCRIPTION="A Brick Breaker with 50 levels of game and 11 special levels"
HOMEPAGE="http://linux.tlk.fr/"

#SRC_URI="http://linux.tlk.fr/games/TecnoballZ/download/${P}.tgz"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-*"
IUSE=""

DEPEND="virtual/libc
	media-libs/libmikmod
	media-libs/libogg
	>=media-libs/libsdl-1.2
	media-libs/libvorbis
	media-libs/sdl-mixer
	media-libs/smpeg
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXt"

pkg_setup() {
	games_pkg_setup
	if ! built_with_use media-libs/sdl-mixer mikmod ; then
		die "Please emerge sdl-mixer with USE=mikmod"
	fi
}

dir=${GAMES_DATADIR}/${PN}

src_unpack() {
	cvs_src_unpack
	mv "${WORKDIR}/${PN}" "${WORKDIR}/${P}"
	find "${WORKDIR}" -name CVS -type d | xargs rm -r
	cd "${S}"

	sed -i {,src/}Makefile.am \
		-e "s:\$(prefix)/games:${GAMES_DATADIR}:" \
		-e "s:/var/games:${GAMES_STATEDIR}:" \
		-e "s:\$(mandir):/usr/share/man:" \
		|| die "sed Makefile.am failed"

	# ressources.cc is the correct filename
	sed -i src/ressources.cc \
		-e "s:/var/lib/games:${GAMES_STATEDIR}:" \
		-e "s:/usr/share/games:${GAMES_DATADIR}:" \
		|| die "sed ressources.cc failed"

	sed -i config* \
		-e "s:/usr/local/share:${GAMES_DATADIR}:" \
		|| die "sed config* failed"

	[[ ! -e autotools ]] && mkdir autotools
	eautoreconf || die "eautoreconf failed"
}

src_compile() {
	egamesconf BINDIR="${GAMES_BINDIR}" \
		DATADIR="${GAMES_DATADIR}/${PN}" \
		VARDIR="${GAMES_STATEDIR}" \
		|| die "egamesconf failed"
	emake || die "emake failed"
}

src_install() {
	dogamesbin src/${PN} || die "dogamesbin failed"

	insinto "${dir}"
	doins -r src/TecnoballZ/* || die "doins TecnoballZ failed"
	find "${D}" -name Makefile\* | xargs rm -r
	find "${D}" -name .xvpics | xargs rm -r

	make_desktop_entry ${PN} "TecnoballZ"

	newman man/${PN}.? ${PN}.6
	dodoc AUTHORS CHANGES README

	insinto "${GAMES_STATEDIR}"
	insopts -m 660
	doins ${PN}.hi || die "doins ${PN}.hi failed"

	prepgamesdirs
}