# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils games

DESCRIPTION="A Brick Breaker with 50 levels of game and 11 special levels"
HOMEPAGE="http://linux.tlk.fr/"
SRC_URI="http://linux.tlk.fr/games/TecnoballZ/download/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE=""

DEPEND="virtual/libc
	media-libs/libmikmod
	media-libs/libogg
	>=media-libs/libsdl-1.2
	media-libs/libvorbis
	media-libs/sdl-mixer
	media-libs/smpeg
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXt"

dir=${GAMES_DATADIR}/${PN}

pkg_setup() {
	games_pkg_setup
	if ! built_with_use media-libs/sdl-mixer mikmod ; then
		die "Please emerge sdl-mixer with USE=mikmod"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i Makefile \
		-e "s:/usr/local:/usr:" \
		|| die "sed Makefile failed"

	sed -i src/Makefile \
		-e '/^CC/d; /^CXX/d; /^PREFIX/d;' \
		-e "s:^EXEDIR.*=:EXEDIR=${GAMES_BINDIR}:" \
		-e "s:^MANDIR.*=:MANDIR=/usr/share/man:" \
		-e "s:^DATADIR.*=:DATADIR=${GAMES_DATADIR}/${PN}:" \
		-e "s:^SCOREDIR.*=:SCOREDIR=${GAMES_STATEDIR}:" \
		|| die "sed src/Makefile failed"

	mkdir src/TecnoballZ/bitmaps
	mv src/TecnoballZ/*.bmp src/TecnoballZ/bitmaps

	# ressources.cc is the correct filename
	sed -i src/ressources.cc \
		-e "s:/var/lib/games:${GAMES_STATEDIR}:" \
		-e "s:/usr/share/games:${GAMES_DATADIR}:" \
		|| die "sed ressources.cc failed"

	sed -i config* \
		-e "s:/usr/local/share:${GAMES_DATADIR}:" \
		|| die "sed config* failed"
}

src_compile() {
	egamesconf BINDIR="${GAMES_BINDIR}" \
		DATADIR="${GAMES_DATADIR}/${PN}" \
		VARDIR="${GAMES_STATEDIR}" \
		|| die "egamesconf failed"
	emake || die "emake failed"
}

src_install() {
	dogamesbin src/${PN} || die "dogamesbin failed"

	insinto "${dir}"
	doins -r src/TecnoballZ/* || die "doins TecnoballZ failed"

	make_desktop_entry ${PN} "TecnoballZ"

	newman man/${PN}.? ${PN}.6
	dodoc AUTHORS CHANGES README

	insinto "${GAMES_STATEDIR}"
	insopts -m 660
	doins ${PN}.hi || die "doins ${PN}.hi failed"

	prepgamesdirs
}