jabberd-1.4.4-r3.ebuild

jabberd-1.4.4-r3.ebuild (text/plain), 2.93 KB, created by Paul Bredbury on 2006-09-28 00:25:45 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/jabberd/jabberd-1.4.4-r3.ebuild,v 1.1 2006/09/27 22:31:36 nelchael Exp $

inherit eutils

DESCRIPTION="Open-source Jabber server"
HOMEPAGE="http://www.jabber.org"
SRC_URI="http://download.jabberd.org/jabberd14/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="debug ipv6 mysql pool-debug postgres ssl"

# Block against jabberd-2* is needed - both packages install the same files.
# jabberd-2* needs to be back at SLOT="0"
DEPEND=">=net-im/jabber-base-0.01
	>=dev-libs/pth-1.4.0
	dev-libs/expat
	mysql? ( dev-db/mysql )
	postgres? ( dev-db/postgresql )
	ssl? ( >=dev-libs/openssl-0.9.6i )
	!=net-im/jabberd-2*"

S="${WORKDIR}/${P}"

pkg_setup() {
	if use postgres && use mysql; then
		eerror "Please select mysql or postgres"
		die "Please select mysql or postgres"
	fi

	if use ipv6; then
		ewarn "Without full ipv6 support, jabberd will show the error:"
		ewarn '   "mio unable to listen"'
		ewarn "To fix this, emerge jabberd without the ipv6 USE flag."
	fi
}

src_unpack() {
	unpack "${A}"

	# Resolves bug #147342
	epatch "${FILESDIR}/${P}-openssl-0.9.8.patch"
}

src_compile() {
	unset LC_ALL LC_CTYPE

	# Broken configure script - can't use "use_enable"
	local myconf
	use debug && myconf="${myconf} --enable-debug"
	use pool-debug && myconf="${myconf} --enable-pool-debug"
	use ipv6 && myconf="${myconf} --enable-ipv6"
	use ssl && myconf="--enable-ssl"

	econf \
		${myconf} \
		$(use_with mysql) \
		$(use_with postgres postgresql ) \
		--sysconfdir=/etc/jabber \
		|| die "econf failed"

	# Broken parallel build
	emake -j1 || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"

	newinitd "${FILESDIR}"/${P}.init jabber || die "newinitd failed"

	# net-im/jabber-base provides needed directories
	rm -rf "${D}/var"
	mv "${D}"/etc/jabber/jabber{,d}.xml
	mv "${D}"/etc/jabber/jabber{,d}.xml.dist

	sed -i \
		-e 's,/var/lib/spool/jabberd,/var/spool/jabber,g' \
		-e 's,/var/lib/log/jabberd,/var/log/jabber,g' \
		-e 's,/var/lib/run/jabberd,/var/run/jabber,g' \
		-e 's,jabber.pid,jabberd14.pid,g' \
		"${D}"/etc/jabber/jabberd.xml{,.dist} \
		|| die "sed failed"
}

pkg_postinst() {
	ewarn "The various IM transports for jabber are now separate packages,"
	ewarn "which you will need to install separately if you want them:"
	ewarn "   net-im/jit - ICQ transport"
	ewarn "   net-im/pymsn-t - MSN transport"
	ewarn "   net-im/jud - Jabber User Directory"
	ewarn "   net-im/yahoo-transport - Yahoo IM system"
	ewarn "   net-im/mu-conference - Jabber multi user conference"
	ewarn
	ewarn "If upgrading from an older version, please stop jabberd BEFORE"
	ewarn 'updating the init.d script, or you will end with a "dead" server.'
	ewarn
	ewarn "The configuration filename has changed:"
	ewarn "   Configure your server in /etc/jabber/jabberd.xml"
	echo
	ebeep
}