astromenace-bin-0.32_beta.ebuild

astromenace-bin-0.32_beta.ebuild (text/plain), 1.37 KB, created by Paul Bredbury on 2006-09-27 11:36:41 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils versionator games

MY_PN=${PN%-bin}
MY_PV=$(delete_all_version_separators)
MY_PV=${MY_PV/beta/b}

DESCRIPTION="Modern 3D space shooter with spaceship upgrade possibilities"
HOMEPAGE="http://www.viewizard.com/astromenace/index_linux.php"
SRC_URI="http://www.viewizard.com/download/amenace${MY_PV}.tar.bz2"

# See License.txt
LICENSE="astromenace"
KEYWORDS="~amd64 ~x86"
IUSE=""
SLOT="0"
RESTRICT="strip"

# libvorbis provides libvorbisfile.so
RDEPEND="x86? (
		>=media-libs/libsdl-1.2.6
		>=media-libs/sdl-image-1.2.4
		>=media-libs/sdl-mixer-1.2.6
		>=media-libs/libogg-1.1
		>=media-libs/libvorbis-1.1
		>=media-libs/jpeg-6b
		media-libs/libmikmod
		virtual/glu
		virtual/opengl
		x11-libs/libX11
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libXext
		x11-libs/libXrandr
		x11-libs/libXrender )
	amd64? ( app-emulation/emul-linux-x86-sdl )"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${MY_PN}

src_install() {
	local dir=${GAMES_PREFIX_OPT}/${MY_PN}
	local exe="AstroMenace"

	insinto "${dir}"
	doins -r * || die "doins failed"
	exeinto "${dir}"
	doexe "${exe}" || die "doexe failed"

	games_make_wrapper ${MY_PN} "./${exe}" "${dir}"
	newicon ${MY_PN}_128.png ${MY_PN}.png || die "newicon failed"
	make_desktop_entry ${MY_PN} "Astro Menace" ${MY_PN}.png

	prepgamesdirs
}