wxGTK-2.7.0_p1.ebuild

wxGTK-2.7.0_p1.ebuild (text/plain), 1.78 KB, created by Federico Fissore on 2006-09-20 15:01:57 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/wxGTK/wxGTK-2.6.3.2.ebuild,v 1.5 2006/08/05 14:10:04 leio Exp $

inherit wxlib gnuconfig versionator flag-o-matic

DESCRIPTION="GTK+ version of wxWidgets, a cross-platform C++ GUI toolkit and
wxbase non-gui library"

SRC_URI="mirror://sourceforge/wxwindows/wxWidgets-${PV/_p/-}.tar.bz2"

SLOT="2.7"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="gnome joystick odbc opengl sdl X"
RDEPEND="${RDEPEND}
	X? ( opengl? ( virtual/opengl )
		>=x11-libs/gtk+-2.0
		>=dev-libs/glib-2.0
		media-libs/tiff )
	odbc? ( dev-db/unixODBC )
	x86? ( sdl? ( >=media-libs/libsdl-1.2 ) )
	amd64? ( sdl? ( >=media-libs/libsdl-1.2 ) )
	ppc? ( sdl? ( >=media-libs/libsdl-1.2 ) )"

DEPEND="${RDEPEND}
	${DEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/wxWidgets-${PV/_p/-}

pkg_setup() {
	if use X; then
		einfo "To install only wxbase (non-gui libs) use USE=-X"
	else
		einfo "To install GUI libraries, in addition to wxbase, use USE=X"
	fi
}

src_compile() {
	gnuconfig_update
	append-flags -fno-strict-aliasing
	myconf="${myconf}
		$(use_with sdl)
		$(use_enable joystick)"

	if use X; then
		myconf="${myconf}
			$(use_enable opengl)
			$(use_with opengl)
			$(use_with gnome gnomeprint)
			$(use_with gnome gnomevfs)"
	fi

	use X && configure_build gtk2 unicode "${myconf} --with-gtk=2"
	use X || configure_build base unicode "${myconf} --disable-gui"
}

src_install() {
	use X && install_build gtk2
	use X || install_build base

	wxlib_src_install
}

pkg_postinst() {
	einfo "dev-libs/wxbase has been removed from portage."
	einfo "wxBase is installed with wxGTK, as one of many libraries."
	einfo "If only wxBase is wanted, -X USE flag may be specified."
}