hcdcat-1.01b.ebuild

hcdcat-1.01b.ebuild (text/plain), 1.37 KB, created by Przemyslaw Maciag (RETIRED) on 2006-09-17 15:04:22 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils qt3

MY_PN="${PN/h/}"

DESCRIPTION="Hyper's CdCat is a graphical (Qt based) filesystem catalog utility"
HOMEPAGE="http://cdcat.sourceforge.net/"
SRC_URI="http://cdcat.sourceforge.net/${MY_PN}-${PV}.tar.bz2"

LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="$(qt_min_version 3.3)
		>=dev-libs/expat-1.95.2
		>=dev-libs/libpcre-3.9
		>=sys-libs/zlib-1.1.4"

S="${WORKDIR}/CdCat-${PV}"

src_unpack() {
	unpack ${A}

	cd ${S}
	epatch ${FILESDIR}/${PN}-gcc4.patch
	epatch ${FILESDIR}/${PN}-desktop_file.patch
	epatch ${FILESDIR}/${PN}-gentoo_langpaths.patch
}

src_compile() {
	cd src

	${QTDIR}/bin/qmake ${MY_PN}.pro \
		QMAKE_CXXFLAGS_RELEASE="${CXXFLAGS}" \
		QMAKE=${QTDIR}/bin/qmake \
		QMAKE_RPATH= \
		"CONFIG+=\"no_fixpath thread\"" \
		|| die "qmake failed"

	emake || die "make failed"
}

src_install() {
	newbin ${S}/src/${MY_PN} ${PN}
	dodoc Authors ChangeLog TRANSLATORS_README TODO README*

	# desktop icon and menu file
	newicon ${MY_PN}.png ${PN}.png
	newmenu ${S}/KDE/${MY_PN}.desktop ${PN}.desktop

	# Install language translations only when set in in LINGUAS
	cd ${S}/src/lang
	insinto /usr/share/${PN}/translations
	for i in ${LINGUAS}; do
		if [ -f ${MY_PN}_${i}.qm ]; then
			newins ${MY_PN}_${i}.qm ${PN}_${i}.qm
		fi;
	done;
}