# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="Game data for the demo of FreeSpace - The Great War"
HOMEPAGE="http://www.volition-inc.com/fs/"
SRC_URI="http://www.pxo.net/files/fsdemo10.exe
	http://icculus.org/~taylor/freespace/updates/fsdemo-${PV}-x86.run"

LICENSE="freespace1-demo"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="games-util/loki_patch
	app-arch/unshield"

src_unpack() {	
	mkdir "${S}" "${WORKDIR}/installer" "${WORKDIR}/patch"
	
	# Unpack the 1.0 installer files.
	cd "${WORKDIR}/installer"
	unzip -q "${DISTDIR}/fsdemo10.exe"
	unshield x data1.cab
	
	# Prepare the files to be patched.
	mv "Data_files/Data" "Program_Executable_Files/readme.txt" "${S}"

	# Unpack the patch.
	cd "${WORKDIR}/patch"
	tail -n +$(sed -n "s:^skip=::p" "${DISTDIR}/fsdemo-${PV}-x86.run") "${DISTDIR}/fsdemo-${PV}-x86.run" | tar zx
	
	# Apply the patch.
	loki_patch patch.dat "${S}"
}

src_compile() {
	einfo "Nothing to compile!"
}

src_install() {
	dodoc readme.txt
		
	insinto "${GAMES_DATADIR}/freespace1-demo"
	doins Data/*.vp
	
	prepgamesdirs
}