chocolate-doom-0.1.4.ebuild

chocolate-doom-0.1.4.ebuild (text/plain), 1.18 KB, created by Paul Bredbury on 2006-09-12 10:37:44 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="Doom port designed to act identically to the original game"
HOMEPAGE="http://www.chocolate-doom.org"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

DEPEND="media-libs/libsdl
	media-libs/sdl-mixer
	media-libs/sdl-net"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Change default search path for IWAD
	sed -i \
		-e "s:/usr/share/games/doom:${GAMES_DATADIR}/doom-data:" \
		src/d_main.c || die "sed main.c failed"
}

src_compile() {
	egamesconf || die "egamesconf failed"
	emake || die "emake failed"

	cd man
	emake || die "emake man failed"
}

src_install() {
	dogamesbin src/${PN} || die "dogamesbin failed"

	doicon data/${PN}.png || die "doicon failed"
	make_desktop_entry ${PN} "Chocolate Doom"

	doman man/${PN}.6 || die "doman failed"
	dodoc AUTHORS BUGS ChangeLog NEWS README TODO || die "dodoc failed"

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	echo
	elog "To play the original Doom levels, place doom.wad and/or doom2.wad"
	elog "into ${GAMES_DATADIR}/doom-data, then run: ${PN}"
	echo
}