ebuild for games-fps/chocolate-doom-0.1.4

chocolate-doom-0.1.4.ebuild (text/plain), 1.29 KB, created by Davide Cendron (RETIRED) on 2006-09-12 07:59:14 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

DESCRIPTION="port of the Doom source code which is designed to act as identically as possible to the original Doom executables"
HOMEPAGE="http://www.chocolate-doom.org"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

DEPEND="media-libs/libsdl
		media-libs/sdl-mixer
		media-libs/sdl-net"

src_unpack() {
	unpack ${A} || die "unpack failed"

	# Change default search path for IWAD in /usr/share/games/doom-data
	cd ${S}
	sed -i -e "s:\/usr\/share\/games\/doom:\/usr\/share\/games\/doom-data:" src/d_main.c || die "sed failed"
}

src_compile() {
	egamesconf || die "egamesconf failed"

	emake || die "emake failed"

	cd man
	emake || die "emake man failed"
}

src_install() {
	dogamesbin src/${PN} || die "dogamesbin failed"
	doman man/${PN}.6 || die "doman failed"
	dodoc {AUTHORS,BUGS,ChangeLog,NEWS,README,TODO} || die "dodoc failed"
	prepgamesdirs
}

pkg_postinst() {
	echo
	einfo "To play the original Doom levels, place doom.wad and/or doom2.wad"
	einfo "into ${GAMES_DATADIR}/doom-data, then run: "
	einfo
	einfo "  ${PN}"
	einfo
	einfo "See manpage or documentation for command-line parameters explanation"
	echo
	
	games_pkg_postinst
}