# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit flag-o-matic eutils toolchain-funcs

PATCHLEVEL="1"
DESCRIPTION="An mpeg library for linux"
HOMEPAGE="http://heroinewarrior.com/libmpeg3.php3"
SRC_URI="mirror://sourceforge/heroines/${P}-src.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="mmx css"

RDEPEND="sys-libs/zlib
	media-libs/jpeg
	media-libs/a52dec"
DEPEND="${RDEPEND}
	mmx? ( dev-lang/nasm )"

src_unpack() {
	unpack ${A}
	cd "${S}"

	if [[ $(gcc-version) == "3.3" ]]; then
		eerror "You're using an old version of GCC, but this package is"
		eerror "designed to work only with GCC 3.4 or later."
		eerror "Please upgrade your GCC or change the selected profile"
		eerror "and then merge this again."
		die "Package won't build with GCC 3.3."
	fi

	# The Makefile is patched to install the header files as well.
	# This patch was generated using the info in the src.rpm that
	# SourceForge provides for this package.

	sed -i -e "/LIBS = /s:$: -L\${ROOT}usr/$(get_libdir) -la52:" Makefile

	epatch "${FILESDIR}/${P}-makefile.patch"
	epatch "${FILESDIR}/${P}-mpeg3split.patch"
	use mmx && epatch "${FILESDIR}/${P}-textrel.patch"
	epatch "${FILESDIR}/${P}-gnustack.patch"

	if ! use mmx; then
		sed -i -e 's:^NASM =.*:NASM =:' \
			-e 's|^HAVE_NASM :=.*|HAVE_NASM=n|' \
			-e 's|USE_MMX = 1|USE_MMX = 0|' \
			Makefile
	fi

	if ! use css; then
		sed -i 's:USE_CSS = 1:USE_CSS = 0:' Makefile
	fi
}

src_compile() {
	local obj_dir=$(uname --machine)

	mkdir $obj_dir

	rm -f ${obj_dir}/*.o &> /dev/null

	emake CC="$(tc-getCC)" || die "make failed"
}

src_install() {
	# This patch patches the .h files that get installed into /usr/include
	# to show the correct include syntax '<>' instead of '""'  This patch
	# was also generated using info from SF's src.rpm
	epatch ${FILESDIR}/gentoo-p2.patch
	make DESTDIR="${D}/usr" LIBDIR="$(get_libdir)" install || die
	dohtml -r docs
}