sipp-1.1_rc5.ebuild

sipp-1.1_rc5.ebuild (text/plain), 1.31 KB, created by Octavio Ruiz (Ta^3) on 2006-08-30 03:23:47 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit toolchain-funcs eutils

SNAPSHOT="2006-03-20"

DESCRIPTION="A free Open Source test tool and traffic generator for the SIP protocol"
HOMEPAGE="http://sipp.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P/_/}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

IUSE="debug ssl pcap"

DEPEND="virtual/libc
		sys-libs/ncurses
		pcap? ( net-libs/libpcap
				net-libs/libnet )
		ssl? ( dev-libs/openssl )"

S=${WORKDIR}/${PN}.cumulus.${SNAPSHOT}

src_unpack() {
	unpack "${A}"
	cd "${S}"

	sed -i \
		-e "s:^CC_linux=.*:CC_linux=$(tc-getCC):" \
		-e "s:^CPP_linux=.*:CPP_linux=$(tc-getCXX):" \
		-e "s:^CFLAGS_linux=\(.*\):CFLAGS_linux=${CFLAGS} \1:" \
		-e "s:^CPPFLAGS_linux=\(.*\):CPPFLAGS_linux=${CXXFLAGS} \1:" \
		-e "s:^INCDIR_linux=.*:INCDIR_linux=-I. -I/usr/include/openssl:" \
	Makefile || die "sed failed"

	if use debug; then
		sed -i -e 's:$(DEBUG_FLAGS):-g -pg:' \
		Makefile || die "sed failed"
	fi
}

src_compile() {
	local makeopt

	use pcap && makeopt="pcapplay"
	use ssl && makeopt="${makeopt:+${makeopt}_}ossl"

	emake -j1 ${makeopt} || die "make failed"
}

src_install() {
	dobin sipp
	dodoc *.txt sipp.dtd
	use pcap && {
		insinto /usr/share/${PN}/pcap
		doins ${S}/pcap/*pcap
		}
}