# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_P=${P}jo-III

DESCRIPTION="graphical wine tool for installing Windows programs under wine"
HOMEPAGE="http://www.von-thadden.de/Joachim/WineTools/index.html"
SRC_URI="http://ds80-237-203-29.dedicated.hosteurope.de/wt/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls"

RDEPEND="app-emulation/wine
	nls? ( sys-devel/gettext )
	x11-misc/xdialog"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i \
		-e '/^DIALOG=/s:=.*:=`which Xdialog`:' \
		-e 's:/usr/local/winetools:/usr/share/winetools:g' \
		-e 's:/usr/local/share/locale:/usr/share/locale:g' \
		-e 's:${BASEDIR}/doc:/usr/share/doc/'${PF}':' \
		-e '/README/s:cat:zcat:' \
		findwine wt${PV}jo || die
}

src_install() {
	dodoc doc/README.* doc/*.txt
	dohtml doc/*.html doc/*.gif

	if use nls ; then
		local i
		for i in po/*.po ; do
			i=${i##*/}
			i=${i%.po}
			dodir /usr/share/locale/${i}/LC_MESSAGES
			msgfmt po/${i}.po -o "${D}"/usr/share/locale/${i}/LC_MESSAGES/wt${PV}.mo || die "msgfmt ${i} failed"
		done
	fi

	exeinto /usr/share/winetools
	doexe wt${PV}jo chopctrl.pl findwine listit || die "doexe"

	insinto /usr/share/winetools
	doins -r *.reg gettext.sh.dummy icon scripts 3rdParty || die "doins"

	dodir /usr/bin
	dosym /usr/share/winetools/findwine /usr/bin/findwine
	dosym /usr/share/winetools/wt${PV}jo /usr/bin/wt2
	dosym /usr/share/winetools/wt${PV}jo /usr/bin/winetools

	doicon icon/winetools.png || die
	make_desktop_entry winetools Winetools wine Emulation
}