# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils
DESCRIPTION="Embedded web server for use by embedded devices and applications"
HOMEPAGE="http://www.appwebserver.org/"
myver=${PV%_p*}
mypl=${PV#*_p}
SRC_URI="http://www.appwebserver.org/software/appWeb-src-${myver}-${mypl}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="session minimal cgi ssl uclibc++"
DEPEND=""

S=${WORKDIR}/appWeb-${myver}

src_unpack() {
	unpack "${A}"
	use uclibc++ && sed -i 's/stdc++/uClibc++/' "${S}/conf/make.os.LINUX"
}

src_compile() {
	cd "${S}"
	./configure --prefix=/usr/appWeb --disable-test --type=RELEASE \
		$(use_enable minimal squeeze) \
		$(use_enable session) \
		$(use_with cgi cgi=loadable) \
		$(use_with ssl openssl=loadable) \
		$(use_with ssl openssl-libs=ssl) \
		|| die "configure failed"
		
#		$(use_enable ipv6) \
#		$(use_enable static) \
	emake || die "emake failed"
}

src_install() {
	emake ROOT_DIR="${D}" install || die "emake install failed"
	newinitd ${FILESDIR}/appweb.init.d appweb
	newconfd ${FILESDIR}/appweb.conf.d appweb

	# move conf to more sane location
	dodir /etc/appWeb
	mv ${D}/usr/appWeb/appWeb.conf ${D}/etc/appWeb/

	# create log dir
	keepdir /var/log/appWeb
	
	# we have our own scripts
	rm -rf ${D}/etc/rc.d
}