dev-python/hachoir/hachoir-0.5.2.ebuild

hachoir-0.5.2.ebuild (text/plain), 1.44 KB, created by TGL on 2006-08-23 12:10:49 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit distutils

DESCRIPTION="Python modules and tools for viewing/editing binary files"
HOMEPAGE="http://hachoir.org"
TESTS_URL="http://www.haypocalc.com/hachoir/testcase/"
SRC_URI="http://cheeseshop.python.org/packages/source/h/hachoir/${P}.tar.gz
	test? (
		${TESTS_URL}/yellowdude.3ds
		${TESTS_URL}/logo-Kubuntu.png
		${TESTS_URL}/mbr_linux_and_ext
		${TESTS_URL}/KDE_Click.wav
		${TESTS_URL}/test.txt.gz
		${TESTS_URL}/flashmob.mkv
		${TESTS_URL}/10min.mkv
		${TESTS_URL}/CD_0008_5C48_1m53s.cda
		${TESTS_URL}/wormux_32x32_16c.ico
		${TESTS_URL}/audio_8khz_8bit_ulaw_4s39.au
		${TESTS_URL}/sheep_on_drugs.mp3
	)"
# To update SRC_URI of test cases, try this:
# sed -n '/^files = (/,/^)/s|^ *("\([^"]\+\).*|${TESTS_URL}/\1|p' run_testcase.py

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="test"

DEPEND="=dev-lang/python-2.4*
	test? ( dev-python/setuptools )
	dev-python/docutils"
RDEPEND="=dev-lang/python-2.4*
	dev-python/urwid
	dev-python/pyxml"

DOCS="AUTHORS BUGS NEWS"

src_unpack() {
	unpack ${P}.tar.gz
	if use test ; then
		mkdir -p "${S}/testcase"
		local testcase
		for testcase in ${A} ; do
			[[ ${testcase} == ${P}.tar.gz ]] && continue
			cp "${DISTDIR}/${testcase}" "${S}/testcase"
		done
	fi
}

src_compile() {
	distutils_src_compile
	make doc || die "Failed to \"make doc\""
}

src_install() {
	distutils_src_install
	dohtml doc/*
}