# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/quake1-textures/quake1-textures-20050820.ebuild,v 1.1 2006/06/19 20:28:38 wolf31o2 Exp $

inherit eutils games

DEBASER_PV="1"
DEBASER_FILE="DebaserTextures_v${DEBASER_PV}.zip"
MY_SKINS="SKINSbmodels-48files-4-23-05.zip"
MY_TEXTURES="qrp-textures-549files-7-22-06.zip"

DESCRIPTION="Collection of graphical improvements for Quake 1"
HOMEPAGE="http://facelift.quakedev.com/
	http://hosted.planetquake.gamespy.com/starbuck/"
SRC_URI="http://facelift.quakedev.com/download/${MY_SKINS}
	http://facelift.quakedev.com/download/${MY_TEXTURES}
	http://files.quakeonline.net/textures/qrp/${MY_TEXTURES}
	http://qexpo.quakedev.com/uploaded/6/${DEBASER_FILE}"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debaser X"

RDEPEND="X? ( || (
		games-fps/darkplaces
		games-fps/joequake
		games-fps/tenebrae
		games-fps/ezquake-bin
		games-fps/fuhquake-bin ) )"
DEPEND="app-arch/unzip"

S=${WORKDIR}
dir=${GAMES_DATADIR}/quake1

src_unpack() {
	unpack ${MY_SKINS} ${MY_TEXTURES}

	# Show the "retexturing project" words at the very start of a new game
	mv -f quake-QRP.tga textures/quake.tga
	# Move the skin textures to join the others
	mv *.tga textures

	unpack ${DEBASER_FILE}
	# Move Debaser textures to join the others
	if use debaser ; then
		# Debaser overrides Quake Rexturing Project
		mv -f *.tga textures
	else
		# Use Debaser texture only when it is not already supplied
		local f
		for f in *.tga ; do
			if [[ ! -f "textures/${f}" ]] ; then
				mv "${f}" textures
			fi
		done
	fi
}

src_install() {
	insinto "${dir}"/id1
	doins -r textures \
		|| die "doins textures failed"

	# Set up symlink, for the demo levels to include the textures
	dosym "${dir}/id1/textures" "${dir}/demo/textures"

	# Support specific engines which need their own directory names
	dosym "${dir}/id1/textures" "${dir}/tenebrae/override"
	dosym "${dir}/id1/textures" "${dir}/fuhquake/textures"

	dodoc *.txt

	prepgamesdirs
}