quake1-soa-1.ebuild

quake1-soa-1.ebuild (text/plain), 1.02 KB, created by Paul Bredbury on 2006-08-19 15:36:40 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DESCRIPTION="Scourge of Armagon mission pack for Quake 1"
HOMEPAGE="http://www.idsoftware.com/games/quake/quake-mp1/"
SRC_URI=""

# See manual.txt
LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
IUSE="X"

RDEPEND="games-fps/quake1-data
	X? ( games-fps/darkplaces )"
DEPEND=""

S=${WORKDIR}
dir=${GAMES_DATADIR}/quake1

pkg_setup() {
	games_pkg_setup

	cdrom_get_cds Armagon/HIPNOTIC/PAK0.PAK:hipnotic/pak0.pak
}

src_install() {
	insinto "${dir}"/hipnotic
	newins "${CDROM_ROOT}/${CDROM_MATCH}" pak0.pak \
		|| die "newins ${CDROM_MATCH} failed"

	# CDROM_SET starts at 0
	if [[ "${CDROM_SET}" = "0" ]] ; then
		dodoc "${CDROM_ROOT}"/Armagon/*.{TXT,txt}
	else
		dodoc "${CDROM_ROOT}"/*.txt
	fi

	if use X ; then
		# Wrapper for darkplaces engine
		games_make_wrapper darkplaces-soa "darkplaces -hipnotic"
		make_desktop_entry darkplaces-soa "Dark Places (Scourge of Armagon)" darkplaces.png
	fi

	prepgamesdirs
}