Experimental ebuild for Vulture's Eye

vultureseye-2.1.0.ebuild (text/plain), 1.82 KB, created by Elmo Todurov on 2006-08-16 12:47:17 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-roguelike/vultureseye/vultureseye.ebuild,v 1.0 2006/01/19 11:29:00 jcheek Exp $

inherit eutils games

DESCRIPTION="A graphical version of nethack (forked from falconseye)"
HOMEPAGE="http://www.darkarts.co.za/projects/vultures/"
SRC_URI="http://www.darkarts.co.za/projects/vultures/downloads/${PV}/vultures-${PV}-eye.tar.bz2"

KEYWORDS="~x86 ~ppc ~amd64"
LICENSE="nethack"
SLOT="0"
IUSE=""

DEPEND="media-libs/libsdl
	dev-util/yacc
	dev-util/byacc"
RDEPEND="media-libs/libsdl
	media-sound/timidity++
	virtual/mpg123"

S=${WORKDIR}/vultures-2.1.0/nethack # nethack-341-jtp-194a

src_unpack() {
	unpack ${A}
	cd ${S}
	source sys/unix/setup.sh
	cd ../../

	epatch ${FILESDIR}/${PV}-gentoo-paths.patch
	epatch ${FILESDIR}/${PV}-default-options.patch
	epatch ${FILESDIR}/${PV}-fix-makefiles.patch
	sed -i "s:GENTOO_STATEDIR:${GAMES_STATEDIR}/${PN}:" include/unixconf.h || die "setting statedir"
	sed -i "s:GENTOO_HACKDIR:${GAMES_DATADIR}/${PN}:" include/config.h || die "seting hackdir"
}

src_compile() {
	emake -j1 \
		GAME=vultureseye BUILD=nethack \
		CFLAGS="${CFLAGS} -I../include -I../win/vultures \
			`sdl-config --cflags` -DUSE_SDL_SYSCALLS -DVULTURESEYE" \
		|| die "game failed"
	cd doc
	emake || die "doc failed"
}

src_install() {
	emake \
		GAMEPERM=0755 \
		PREFIX=${D}/usr \
		GAME=vultureseye \
		GAMEUID=${GAMES_USER} \
		GAMEGRP=${GAMES_GROUP} \
		GAMEDIR=${D}/${GAMES_DATADIR}/${PN} \
		VARDIR=${D}/${GAMES_STATEDIR}/${PN} \
		SHELLDIR=${D}/${GAMES_BINDIR} \
		install \
		|| die "install failed"
	dosed "s:${D}/::" ${GAMES_BINDIR}/vultureseye
	sed 's:nethack:vultureseye:g' doc/nethack.6 > doc/vultureseye.6
	doman doc/vultureseye.6
	dodoc README 
	prepgamesdirs
	chmod -R g+w ${D}/${GAMES_STATEDIR}
}