# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PV=${PV/./-}
M="mirror://beyondunreal/chaotic"

DESCRIPTION="Miscellaneous enhancement mod"
HOMEPAGE="http://chaotic.beyondunreal.com/"
SRC_URI="${M}/builds/chaosut_v${MY_PV}_full.zip
	${M}/mappacks/chaosut_beta4mappack.zip
	${M}/mappacks/chaosut_gotymappack.zip"

LICENSE="as-is"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="goty"

RDEPEND="games-fps/unreal-tournament-bonuspacks"
DEPEND="games-util/umodpack
	app-arch/unzip"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/unreal-tournament

src_unpack() {
	unpack ${A}

	if use goty ; then
		# Unreal Tournament GOTY is installed, so don't need extra umod
		rm chaosut_gotymappack.umod
	fi

	local f
	for f in *.umod ; do
		echo ">>> Unpacking ${f}"
		# Can ignore collision on Textures/JezzTex.utx - is same file,
		# in beta and goty map packs.
		umod -v -b . -x "${f}" || die "umod ${f} failed"
	done

	mv *.txt Help
}

src_install() {
	insinto "${dir}"
	find -type d -maxdepth 1 -mindepth 1 | xargs doins -r || die "doins failed"

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "Use the 'Mutators' button in UT to select ChaosUT."
	echo
}