# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header$

inherit eutils java-utils-2

DESCRIPTION="Java-based VMPSd for SQL backends"
HOMEPAGE="http://sf.net/projects/vmpsd/"
SRC_URI="mirror://sourceforge/vmpsd/vmpsd-${PV}-src.zip"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="mysql"
RESTRICT="nostrip"
S="${WORKDIR}/src"

_DEPEND="dev-java/commons-logging
	!net-misc/vmpsd"
DEPEND=">=virtual/jdk-1.5
	app-arch/unzip
	dev-java/ant-core
	${_DEPEND}"
RDEPEND=">=virtual/jre-1.5
	mysql? ( >=dev-java/jdbc-mysql-3.0 )
	dev-java/log4j
	${_DEPEND}"

LIBDIR="${WORKDIR}/lib"
CLASSDIR="${WORKDIR}/bin"
JARDIR="${WORKDIR}/distrib"

src_compile() {
	java-pkg_ensure-vm-version-sufficient 1.5
	mkdir ${LIBDIR}
	cd ${LIBDIR}
	java-pkg_jar-from commons-logging
	export S LIBDIR CLASSDIR JARDIR
	ant -f ${FILESDIR}/build.xml || die 'ant build failed'
}

src_install() {
	java-pkg_dojar ${JARDIR}/vmpsd.jar
	java-pkg_addcp /etc/vmpsd
	java-pkg_dolauncher vmpsd --main edu.ufl.icarus.vmpsd.VMPSd --java_args -server
	dodoc ${WORKDIR}/doc/*
	newinitd ${FILESDIR}/vmpsd.rc vmpsd
	insinto /etc/vmpsd
	doins ${FILESDIR}/*.properties
}

pkg_postinst() {
	if has_version '<net-misc/icarus-vmpsd-1.2' ; then
		einfo " "
		einfo "ICARUS VMPSd now supports logging to a database table. See"
		einfo "${ROOT%/}/usr/share/doc/${PVR}/INSTALL.txt.gz."
		einfo " "
	fi
	einfo " "
	einfo "Don't forget to specify your database information in"
	einfo "${ROOT%/}/etc/vmpsd/vmpsd.properties."
	einfo " "
}